#!/usr/bin/perl

use strict;
use warnings;
use Date::Calc qw(Add_Delta_Days Add_Delta_YM Today);
use File::Spec;
use POSIX;

my $directory = './';
my $logfile   = './deleted_files.log';

my @files = _get_filenames( $directory );
@files    = _clean_list( @files );
_delete_files( $directory, $logfile, @files );

###
# Subroutines
###

sub _get_filenames{
   my ($dir) = @_;
   
   opendir my $dirh, $dir or die $!;
   my @files = grep{ /^\w+\_\d{8}-\d{6}\.tar\.gz$/ }readdir $dirh;
   closedir $dirh;
   
   return @files;
}

sub _clean_list{
   my @files = @_;
   
   my @dates;
   
   my @today = Today();
   
   # keep today's files
   push @dates, sprintf "%04d%02d%02d", @today;
   
   # keep files of 5 last days
   for (1..4){
      push @dates, sprintf "%04d%02d%02d", Add_Delta_Days( @today, $_ * -1 );
   }

   # keep files of 11th, 21st of the last 6 months
   for (0..5){
      my ($year,$month,$day) = Add_Delta_YM( @today, 0, $_ * -1 );
      for( 11, 21 ){
         push @dates, sprintf "%04d%02d%02d", $year,$month, $_;
      }
   }

   # filter filenames
   @files = grep{ my ($f) = $_ =~ /^\w+\_(\d{8})/; 
                 !( grep{ $f == $_ }@dates or $f =~ /01$/ )
                }@files;
}

sub _delete_files{
   my ($dir,$log,@files) = @_;
   
   open my $fh_log, '>>', $log or die $!;
   for my $file ( @files ){
      my $time = POSIX::strftime( '%Y%m%d-%H%M%S', localtime);
      my $fqfn = File::Spec->catfile( $dir, $file );
      unlink $fqfn and print $fh_log $time,"\t",$file,"\n";
   }
   close $fh_log;
}