#! /usr/bin/perl
use strict;
use warnings;

# https://www.perl-community.de/bat/poard/thread/18288

use File::Find;                             # for searching for files/directories
use File::Spec::Functions qw( catfile );    # for creating portable file-paths
use Cwd;                                    # for determing current work directory

my @directories = (                         # where do you want to search?
    '/path/to/data/dir',                    # herein are the .ffn files; ADJUST THIS PATH
);

my %match;                                  # storage for matching file paths


# this routine is to be changed to do the job of data extraction and combination
# ADJUST THIS CODE if test run was successful
sub combine_to {

    my $newfile   = shift;
    my $directory = shift;
    my $filesRef  = shift;

    # DEBUG output
    warn <<DEBUGTEXT;
DATADIR: '$directory'
OUTPUTFILE: '$newfile'
DATAFILES: @{$filesRef}

DEBUGTEXT

}


sub find_ffn_files {

    return if ! -d $File::Find::name;       # skip if not a directory

    my $dir = $File::Find::name;            # short name of directory

    opendir my $dh, $dir   or die "Cannot open '$dir': $!\n";
    # read '.ffn'  files from directory and create full file path
    my @files = grep { m/\.ffn$/ } readdir $dh;
    closedir $dh;

    # create hash of array for matches; 
    # we must have found 1 or exactly 2 files
    $match{$dir} = \@files      if @files && 2 >= @files;
}

# search for files and fill @matches
find( \&find_ffn_files, @directories );

# check %match
for my $dir ( keys %match ) {

    # combine found files into 'combined.ffn' in corresponding directory
    combine_to( 'combined.ffn', $dir => $match{$dir} );

}