Problem beim zeilenweisen Einlesen einer Datei in ein Array ! - #111215 (Allgemeines zu Perl)

renee

2008-06-18 17:17

User since
2003-08-04
14371 Artikel
ModeratorIn

Du hast - glaube ich - nicht so ganz verstanden, worauf ich hinaus will.

Hier mal zwei Versionen:

(Vergleich aller Spalten)

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;
use Tie::File;

my $file_a = 'a.txt';
my $file_b = 'b.txt';

tie my @b_lines, 'Tie::File', $file_b or die $!;
open my $fh, '<', $file_a or die $!;

while( my $zeile = <$fh> ){
   chomp $zeile;
   my @spalten = split /;/, $zeile;
   ZEILE: for my $zeile_b ( @b_lines ){
      my @spalten_b = split /;/, $zeile_b;
      
      if( @spalten == @spalten_b ){
         for ( 0..$#spalten ){
            next ZEILE unless $spalten[$_] eq $spalten_b[$_];
         }
         print "Alles klar: $zeile\n";
      }
   }
}

close $fh;
untie @b_lines;

(Ausgabe)

Code: (dl )

C:\Perl>compare.pl
Alles klar: 10_01;23;22364;29864
Alles klar: 10_02;24;22365;29865
Alles klar: 10_04;27;22367;29868
Alles klar: 10_05;23;22323;29834
Alles klar: 10_06;28;2231264;21219864
Alles klar: 10_08;24;222364;3329864
Alles klar: 10_09;23;22364;2986423
Alles klar: 10_12;24;22365;29865
Alles klar: 10_13;25;22366;29866
Alles klar: 10_15;23;22323;29834
Alles klar: 10_17;25;23442364;23229864

(Vergleich komplette Zeile)

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;
use Tie::File;

my $file_a = 'a.txt';
my $file_b = 'b.txt';

tie my @b_lines, 'Tie::File', $file_b or die $!;
open my $fh, '<', $file_a or die $!;

while( my $zeile = <$fh> ){
   chomp $zeile;
    if( grep{ $_ eq $zeile }@b_lines ){
        print "Alles klar: $zeile\n";
    }
}

close $fh;
untie @b_lines;

(Ausgabe)

Code: (dl )

C:\Perl>compare2.pl
Alles klar: 10_01;23;22364;29864
Alles klar: 10_02;24;22365;29865
Alles klar: 10_04;27;22367;29868
Alles klar: 10_05;23;22323;29834
Alles klar: 10_06;28;2231264;21219864
Alles klar: 10_08;24;222364;3329864
Alles klar: 10_09;23;22364;2986423
Alles klar: 10_12;24;22365;29865
Alles klar: 10_13;25;22366;29866
Alles klar: 10_15;23;22323;29834
Alles klar: 10_17;25;23442364;23229864

Jetzt klar, dass Du auch gleich die komplette Zeile vergleichen kannst, wenn Du sowieso alle Spalten durchgehen willst?

Edit:

Oder etwas anders ausgedrück. Stell Dir vor, Du hast in jeder Zeile nicht diese Zahlen, sondern einfach 'abcd' stehen (in a.txt und b.txt). So wie Du es beschrieben hast, willst Du 'abcd' in 'a','b','c','d' teilen und dann 'a' mit 'a' vergleichen. Wenn das gleich ist, vergleichst Du 'b' mit 'b', 'c' mit 'c' und 'd' mit 'd'. Da kannst Du gleich 'abcd' mit 'abcd' vergleichen, weil dann implizit 'a' mit 'a', 'b' mit 'b', 'c' mit 'c' und 'd' mit 'd' verglichen ist...

OTRS-Erweiterungen (http://feature-addons.de/)
Frankfurt Perlmongers (http://frankfurt.pm/)
--

Unterlagen OTRS-Workshop 2012: http://otrs.perl-services.de/workshop.html
Perl-Entwicklung: http://perl-services.de/