#!/usr/bin/perl

# das folgende sollte in *jedem* Programm/Modul zu finden sein
use strict;
use warnings;

# für das lesen und schreiben von Dateien
use IO::File;

# Datei mit den Datensätzen
my $file = 'wuw.txt';

# lese Blockweise ein. Ein Block wird von "@@"
# mit Zeilenendezeichen begrenzt
local $/ = '@@' . "\n";

# öffne Datei zum Lesen
my $fh = IO::File->new( $file, 'r' );
while( my $block = <$fh> ) {

    # springe aus der Schleife wenn der Block leer ist
    last if !$block;

    # entferne das "@@"
    chomp $block;

    # in $. ist die "Nummer" des Blocks
    # öffne Datei zum Schreiben
    my $out = IO::File->new( $. . '.txt', 'w' );

    # ersetze "Jahrgang, Seite" durch zwei Eintraege
    $block =~ s{
        ^
        Jahrgang, \s+ Seite \s+
        \[ \s+ ([0-9]+), \s+ ([0-9]+) \s+ \]
        $
    }{Jahrgang         [ $1 ]
Seite            [ $2 ]}xmsg;

    # ersetze Datum/Aktenz.
    $block =~ s{
        ^
        Datum/Aktenz\. \s+
        \[ \s+ (\d+)\.(\d+)\.(\d+) .*? ([^\s]+) \s+ \]
        $
    }{Tag              [ $1 ]
Monat            [ $2 ]
Jahr             [ $3 ]
Aktenzeichen     [ $4 ]}xms;

    # ersetze Abteilung
    $block =~ s{
        ^
        Abteilung \s+
        \[ \s+ ([^\s]+) \s+ (\d+) \s+ \] .*?
        $
    }{Abteilung        [ $1 ]
Abteilungsnummer [ $2 ]}xms;

    $out->print( $block );
}