use strict;
use warnings;
use File::Find;
use ExtUtils::MM_Unix;
use version;

my $regex = qr{[^A-Za-z0-9:_\-\.]};

my $finde_ungueltiges_zeichen = sub {
    my ($string) = @_;
    my $ret = '';
    for (my $z = 0; $z < length($string); $z ++) {
        if (substr($string,$z,1) =~ $regex) {
            $ret = 'ord('.ord(substr($string,$z,1)).') an Pos. '.$z;
            last;
        }
    }
    $ret;
};

# Dateien aufnehmen
my $scan = sub {
    my %found;
    for my $dir (@_) {
        if (-d $dir) {
            my $topdir = $dir;
            find(
                sub {
                    if (-f $File::Find::name && $File::Find::name =~ /\.pm$/ ) {
                        my $fn = $File::Find::name;
                        $fn =~ s/\Q$topdir//g;
                        $fn =~ s/\//::/g;
                        $fn =~ s/^:://g;
                        $fn =~ s/\.pm//g;
                        if ($fn =~ $regex) {
                            print "Der Modulname '$fn' enthält ungültige(s) Zeichen ".$finde_ungueltiges_zeichen->($fn);
                        }
                        else {
                            $found{$fn} = $File::Find::name;
                        }
                    }
                },
                $dir
            );
        }
    }
    %found;
};
my %found = $scan->(@INC);  # erstmal alle Unterverzeichniss einlesen

# Versionen
if (keys %found) {
    my $zeile = 0;
    foreach my $modul (sort {lc $a cmp lc $b} keys %found) {
        my $version = MM->parse_version($found{$modul});
        if (defined $version && $version ne 'undef') {
            $version =~ s/ //g;
            if ($version =~ $regex) {   # probiere vorher noch eine andere Alternative https://www.perl-community.de/bat/poard/thread/18292/167420
                $version = version->parse($version);
            }
            if ($version =~ $regex) {
                print "Für Modul '$modul' '$found{$modul}' enthält der Versionsstring '$version' ungültige Zeichen\n";
            }
            else {
                print "Gefunden: '$modul' Version '$version'\n";
            }
        }
    }
}