package PseudoHash;

use strict;
use warnings;

use List::Util qw/max/;

# Constructor
# Params:
#   $self   = Existing object reference or package
#   @fields = Field names to be created in the new pseudo hash
# Returns:
#   A new blessed object
sub new {
  my ($self, @fields) = @_;

  my ($class, $layout) = do {
    if (my $class = ref $self) {
      ($class, $self->[0]);
    }
    else {
      ($self, {});
    }
  };

  if (@fields > 0) {
    $layout = { %$layout };
    my $offset = max(0, values %$layout) + 1;

    foreach my $field (@fields) {
      $layout->{$field} = $offset++;
    }
  }

  bless [ $layout ], $class;
}

# Accesses a field of the pseudo hash by name
# Params:
#   $self  = Reference to the pseudo hash
#   $field = Name of the field
# Returns:
#   An lvalue representing the field
sub field : lvalue {
  my ($self, $field) = @_;

  my $offset = $self->[0]->{$field};
  die "No such field '$field' in $self" unless (defined $offset);

  $self->[$offset];
}

use Data::Dumper;

local ($,, $\) = (' ', "\n");

# Create a pseudo hash
my $ph = new PseudoHash(qw/FOO BAR BAZ/);

# Assign and read existing fields
$ph->field('FOO') = 42;
print 'FOO:', $ph->field('FOO');

$ph->field('BAR') = 23;
print 'BAR:', $ph->field('BAR');

# Create a pseudo hash with identical structure as $ph
my $pi = $ph->new();

# Assign and read an existing field
$pi->field('BAR') = 23;
print 'BAR:', $pi->field('BAR');

# Create a pseudo hash with structure based on $ph
my $pj = $ph->new(qw/QUARK/);

# Assign and read an existing field
$pj->field('QUARK') = 'Hallo';
print 'QUARK:', $pj->field('QUARK');

# Show the structure of the pseudo hashes
print Dumper [ $ph, $pi, $pj ];

# Try to access a non-existing field
$ph->field('BOING'); # generates an error