komischer fehler aber wo? (Allgemeines zu Perl)

[thread]14965[/thread]

komischer fehler aber wo?

Leser: 23

Articles: hide open all | hide show old branches

+8 replies

conray

2010-04-22 21:31

User since
2010-02-19
52 Artikel
BenutzerIn
[default_avatar]

Hi @ all

wollte hier mal wieder was anhängen aber irgendwie klappt mein code nicht so ganz :D
es ist das bekannt spiel XXO.

Durchlaufen tut es auch ohne fehler aber die spieler sind immer zwei mal dran ab der 2. runde oO.
und die abfrage ob das feld belegt ist funktioniert auch nur halbseitens..
könnt ihr mir da helfen?

Sorry for smell code i am a newbie :)

Code (perl): (dl )

#/usr/bin/perl
use strict;

print "What's your name Player1?: ";
my $player1 = <STDIN>;
chomp $player1;
print "\nWhat's your name Player2?: ";
my $player2 = <STDIN>;
chomp $player2;

if ($player1 eq $player2) {
  $player2 = $player2."2";
  }


my @field = ("_", "_", "_", "_", "_", "_", "_", "_", "_", "_");
my %valids = (1, 2, 3, 4, 5, 6, 7, 8, 9);
my $name = $player1;
my $roundcount = 1;
my $choose;
my $stone = 'x';
my $win = 0;
my $othername = $player2;
my $tmpname;
my $stone2 = 'o';
my $tmpstone;
my $valid;

system("clear");
while ($roundcount <= 9 ) {
   
  print "|$field[7]|$field[8]|$field[9]|\n";
  print "|$field[4]|$field[5]|$field[6]|\n";
  print "|$field[1]|$field[2]|$field[3]|\n";
  print "\n$name your turn\n";
  print "In which field do you want to set? ";
  $choose = <STDIN>; 
  chomp $choose;
  
  if (exists $valids{$choose} ) {
    $valid = 1; }
  else { 
    $valid = 0; }

  if ($field[$choose] ne '_') {
    if ($field[$choose] eq $stone) {
          print "you had set here before\n";
          }
  else {
          print "$othername had set here before\n";
          }
        $valid = 0;

        }
  else {
    $field[$choose] = $stone;
        }
        
  if ($field[1] eq $stone and $field[2] eq $stone and $field[3] eq $stone) {
            $win = 1; }
  elsif ($field[4] eq $stone and $field[5] eq $stone and $field[6] eq $stone) {
            $win = 1; }
  elsif ($field[7] eq $stone and $field[8] eq $stone and $field[9] eq $stone) {
            $win = 1; }
  elsif ($field[1] eq $stone and $field[4] eq $stone and $field[7] eq $stone) {
            $win = 1; }
  elsif ($field[2] eq $stone and $field[5] eq $stone and $field[8] eq $stone) {
            $win = 1; }
  elsif ($field[3] eq $stone and $field[6] eq $stone and $field[9] eq $stone) {
            $win = 1; }
  elsif ($field[1] eq $stone and $field[5] eq $stone and $field[9] eq $stone) {
            $win = 1; }
  elsif ($field[3] eq $stone and $field[5] eq $stone and $field[7] eq $stone) {
            $win = 1; }
                        
  if ($win eq 1) {
    last;
  }
        
  $roundcount++;
        
  print "$win\n$stone\n$name\n$roundcount\n";

  if ( $valid eq 1) {
  $tmpname = $name;
  $name = $othername;
  $othername = $tmpname;
  $tmpstone = $stone;
  $stone = $stone2;
  $stone2 = $tmpstone;
  system("clear");
  }
  else {
    $roundcount--; }
        
  }
        
print "|$field[7]|$field[8]|$field[9]|\n";
print "|$field[4]|$field[5]|$field[6]|\n";
print "|$field[1]|$field[2]|$field[3]|\n";
if ($win eq 1) {
  print "Congratulations $name you win";
  }
else {
  print "--->DRAW<---";
}

mfg
conray

+3 replies
Linuxer

2010-04-22 21:47
User since
2006-01-27
3881 Artikel
HausmeisterIn
Was genau ist ein Hash und was genau machst Du mit diesem Code?
Code: (dl )

my %valids = (1, 2, 3, 4, 5, 6, 7, 8, 9);
Lies ihn mal als:
Code: (dl )

my %valids = ( 1 => 2, 3 => 4, 5 => 6, 7 => 8, 9 );
Da fehlt doch was, oder?
Entweder ein weiteres Element, oder die passende Logik, wie alle Zahlen als Schlüssel im Hash landen können.
Beispiele:
Code: (dl )

1 2 3 4 5 6 7

my %valids = map { $_ => $_ } 1 .. 9; # oder my %valids; @valids{1..9} = (1 .. 9); # oder my %valids; @valids{1..9} = ();
Wenn mir noch was auffällt, meld ich mich nochmal.
meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!
- +2 replies
- conray
  
  2010-04-22 21:58
  User since
  2010-02-19
  52 Artikel
  BenutzerIn
  der hash war ursprünglich mal ein array :-D
  aber ich habe auf die schnelle nur gefunden wie man checkt ob eine variable in einem hash vorkommt :D
  könnte man es so machen?
  
  Code (perl): (dl )
  
  if(grep $_ eq $choose, @valids)
  
  Danke für die schnelle Antwort
  mfg
  conray
  - Linuxer
    
    2010-04-22 22:05
    
    User since
    2006-01-27
    3881 Artikel
    HausmeisterIn
    
    Könnte man; hätte den Nachteil, dass für jeden Check der gesamte Array durchlaufen werden muss. (Gut, bei max. 9 Elementen nicht ganz so tragisch.)
    Alternativ könnte man auch first aus List::Util verwenden. Das beendet das Durchlaufen beim ersten Treffer.
    
    Ich würd den Hash auf eine der von mir schon genannten Arten füllen und dann mit exists() prüfen ...
    meine Beiträge: I.d.R. alle Angaben ohne Gewähr und auf Linux abgestimmt!
    Die Sprache heisst Perl, nicht PERL. - Bitte Crossposts als solche kenntlich machen!
+4 replies

MatthiasW

2010-04-22 23:02

User since
2008-01-27
367 Artikel
BenutzerIn
[default_avatar]

Hm.. also erstmal würde ich sagen, der Spieler sollte sehen, welche Indizes zu den jeweiligen Zellen gehören. Außerdem wird das erste Element in einem Array per default mit 0 indiziert, aber das ist nur eine Kleinigkeit.

Ich finde ein paar Dinge sollten in eigene Funktionen gepackt werden, wie bspw. das Ausgeben des Spielfeldes oder das Überprüfen ob jemand gewonnen hat.

Damit nicht mehr so viele Variablen gebraucht und getauscht werden müssen, würde ich mir merken, wer gerade an der Reihe ist: 1 = Spieler 1, 0 = Spieler 2, oder umgekehrt. Der Spielstein und Spielername ergibt sich dann daraus.

Außerdem sollte ein getätigter Zug aus den möglichen gelöscht werden.

Ansonsten finde ich das system('clear') nicht so toll und würde stattdessen entweder je nach Betriebssystem etwas anderes tun, oder eine bestimmte Anzahl an Leerzeilen ausgeben (sollte für den Effekt genügen).

Hier ein alternativer Vorschlag:

Code (perl): (dl )

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;

# spielernamen:
print "Player 1: ";
chomp( my $player1 = <STDIN> );

$player1 =~ s/^\s*$/Player1/;

print "Player 2: ";
chomp( my $player2 = <STDIN> );

$player2 =~ s/^\s*$/Player2/;
$player2 .= '2' if $player2 eq $player1;

my @board;     # spielfeld
my $winner;    # gewinner
my $color = 1; # 1 = X, 0 = O

# hauptschleife:
while ( not defined $winner and scalar( grep defined, @board ) != 9 ) {
    draw_board();
    handle_input();
    check_winner();
} # while

# ausgabe des gewinners:
if ( defined $winner ) {
    draw_board();
    say "\nCongratulations ". ($winner eq 'X' ? $player1 : $player2) ."!";
    say "You are the winner!";
} # if
else {
    draw_board();
    say "\nDraw.";
} # else

# spielfeld zeichnen:
sub draw_board {
    print "\n" x 24; # bildschirm "loeschen" (edit)
    
    say "    A | B | C\n   -----------";
    printf(
        "%s:  %s | %s | %s\n". ($_ == 2 ? '' : "   ---+---+---\n"),
        $_ + 1,
        $board[3*$_  ] // ' ',#/
        $board[3*$_+1] // ' ',#/
        $board[3*$_+2] // ' ',#/
    ) for 0 .. 2;
} # draw_board

# eingabe entgegennehmen und behandeln:
sub handle_input {
    my( $name, $sym ) = $color ? ($player1, 'X') : ($player2, 'O');

    print "\nIt's your turn, $name ($sym): ";
    chomp( my $cell = <STDIN> );
    
    if ( $cell =~ /([abcABC])([123])/ ) {
        my( $x, $y ) = ( $1, $2 - 1 );
        $x = { 'a' => 0, 'b' => 1, 'c' => 2 }->{ lc $x };
        
        if ( defined $board[3*$y+$x] ) {
            say "This cell is already taken.";
            <STDIN>;
        } # if
        else {
            $board[3*$y+$x] = $sym;
            $color = !$color; # naechster spieler
        } # else
    } # if
    else {
        say "I'd appreciate something like A1 or b3.";
        <STDIN>;
    } # else
} # handle_input

# ueberpruefen ob jemand gewonnen hat:
sub check_winner {
    my $eq = sub { # edit: diese routine stände wohl besser in einem
        my $cmp = my $r = $board[shift]; # scope neben check_winner
        $r &&= $cmp eq $board[$_] for @_;
        return $r;
    }; # $eq

    # horizontal, vertikal, diagonal:
    for ( 0, 3, 6 ) { return $winner = $board[$_] if $eq->($_, $_+1, $_+2) }
    for ( 0, 1, 2 ) { return $winner = $board[$_] if $eq->($_, $_+3, $_+6) }
    $winner = $board[4] if $eq->(0, 4, 8) or $eq->(6, 4, 2);
} # check_winner

__END__

Last edited: 2010-04-22 23:44:41 +0200 (CEST)

perl -E'*==*",s;;%ENV=~m,..$,,$&+42;e,$==f;$"++for+ab..an;@"=qw,u t,,print+chr;sub f{split}say"@{=} me"'

+3 replies

conray

2010-04-23 00:56

User since
2010-02-19
52 Artikel
BenutzerIn
[default_avatar]

der code ist auch schön aber ich versteh den nicht so ganz :D ( wie erwähnt newbie :D )
was für eine lib ist denn 5.010?
da ich wie gesagt das ganze an die EierlegendeWollMilchSau.pl hängen wollte widerstrebts mir jetzt einfach deinen Code daranzu nageln :D (verständlich)

hab jetzt die arrayabfrage geändert nun geht alles (fänomenal :D )

Code (perl): (dl )

#/usr/bin/perl
use strict;

  print "What's your name Player1?: ";
  my $player1 = <STDIN>;
  chomp $player1;
  print "\nWhat's your name Player2?: ";
  my $player2 = <STDIN>;
  chomp $player2;

  if ($player1 eq $player2) {
    $player2 = $player2."2";
    }


  my @field = ("_", "_", "_", "_", "_", "_", "_", "_", "_", "_");
  my @valids = (1, 2, 3, 4, 5, 6, 7, 8, 9);
  my $name = $player1;
  my $roundcount = 1;
  my $choose;
  my $stone = 'x';
  my $win = 0;
  my $othername = $player2;
  my $tmpname;
  my $stone2 = 'o';
  my $tmpstone;
  my $valid; 

  system("cls");
  while ($roundcount <= 9 ) {

   
   print "|$field[7]|$field[8]|$field[9]|    |7|8|9|\n";
   print "|$field[4]|$field[5]|$field[6]|    |4|5|6|\n";
   print "|$field[1]|$field[2]|$field[3]|    |1|2|3|\n";
   print "\n$name your turn\n";
   print "In which field do you want to set? ";
   $choose = <STDIN>; 
   chomp $choose;
   
   if(grep $_ eq $choose, @valids) {
     $valid = 1; }
   else { 
     $valid = 0; } 

   if ($field[$choose] ne '_') {
     if ($field[$choose] eq $stone) {
           print "you had set here before\n";
           }
   else {
           print "$othername had set here before\n";
           }
         $valid = 0;

        }
   else {
     $field[$choose] = $stone;
         }
        
    if ($field[1] eq $stone and $field[2] eq $stone and $field[3] eq $stone) {
             $win = 1; }
    elsif ($field[4] eq $stone and $field[5] eq $stone and $field[6] eq $stone) {
             $win = 1; }
    elsif ($field[7] eq $stone and $field[8] eq $stone and $field[9] eq $stone) {
             $win = 1; }
    elsif ($field[1] eq $stone and $field[4] eq $stone and $field[7] eq $stone) {
             $win = 1; }
    elsif ($field[2] eq $stone and $field[5] eq $stone and $field[8] eq $stone) {
             $win = 1; }
    elsif ($field[3] eq $stone and $field[6] eq $stone and $field[9] eq $stone) {
             $win = 1; }
    elsif ($field[1] eq $stone and $field[5] eq $stone and $field[9] eq $stone) {
             $win = 1; }
    elsif ($field[3] eq $stone and $field[5] eq $stone and $field[7] eq $stone) {
             $win = 1; } 
                        
        if ($win eq 1) {
      last;
    }
         
    $roundcount++;
        
        print "$win\n$stone\n$name\n$roundcount\n";
        
        if ( $valid eq 1) {
        $tmpname = $name;
        $name = $othername;
        $othername = $tmpname;
        $tmpstone = $stone;
        $stone = $stone2;
        $stone2 = $tmpstone;
        system("cls");
        }
        else {
          $roundcount--; }
        
  }
        
  print "|$field[7]|$field[8]|$field[9]|    |7|8|9|\n";
  print "|$field[4]|$field[5]|$field[6]|    |4|5|6|\n";
  print "|$field[1]|$field[2]|$field[3]|    |1|2|3|\n";
  if ($win eq 1) {
        print "Congratulations $name you win";
        }
  else {
        print "--->DRAW<---";
        }
  __END__

+2 replies
renee

2010-04-23 08:12

User since
2003-08-04
14371 Artikel
ModeratorIn

2010-04-22T22:56:13 conray
der code ist auch schön aber ich versteh den nicht so ganz :D ( wie erwähnt newbie :D )
was für eine lib ist denn 5.010?

use 5.010; bedeutet ganz einfach, dass man eine Perl Version >= 5.10 nehmen muss. Dass muss man bei bestimmten Code machen, z.B. wenn man das in Perl 5.10.0 neu eingeführte "say" oder "given/when" verwenden will.

Soche "use 5.xxx"-Anweisungen muss man immer dann benutzen, wenn man Features verwenden will, die in einer früheren Perl-Version nicht existierten.
OTRS-Erweiterungen (http://feature-addons.de/)
Frankfurt Perlmongers (http://frankfurt.pm/)
--

Unterlagen OTRS-Workshop 2012: http://otrs.perl-services.de/workshop.html
Perl-Entwicklung: http://perl-services.de/
- conray
  
  2010-04-23 13:30
  
  User since
  2010-02-19
  52 Artikel
  BenutzerIn
  
  ahja das erklärt einiges :)
  Danke für eure Hilfe !
  könnte eigendlich geclosed werden.
  mfg
  conray

View all threads created 2010-04-22 21:31.