2dimensionale Arrays effizient vergleichen (Allgemeines zu Perl)

[thread]15303[/thread]

2dimensionale Arrays effizient vergleichen

Leser: 23

Articles: hide open all | hide show old branches

+9 replies

Gast Juergen

2010-07-22 11:41

Hallo zusammen,

ich habe eine Frage zum Vergleichen von Arrays.
Die Arrays haben folgenden Aufbau:
@arr1 = (
[a, 1, 2, 3],
[b, 4, 4, 3],
[d, 5, 2, H],
);
@arr2 = (
[a, 1, 2, 3],
[c, 8, r, 9],
[d, 5, f, H],
);
Der erste Eintrag ist immer ein-eindeutig und kommt nur ein einziges mal vor in jedem Array!
Wenn ich ein eindimensionales Array hätte, kann ich mir ja anzeigen lassen, welche Elemente gleich sind, welche nur in arr1 sind und welche nur in arr2 sind.
Was ich jedoch noch nicht kann: wenn der erste Eintrag gleich ist, dann müssen auch alle anderen gleich sien, d.h. ist der erste a, dann muss 1,2,3 folgen.
Gibt es eine effiziente Möglichkeit, die beiden Arrays zu vergleichen, damit ich in etwa folgende Ausgabe bekomme:
a 1 2 3 in beiden ok
d in beiden, nicht ok: arr1 d 5 2 H, arr2 d 5 f H
b 4 4 3 nur in arr1
c 8 r 9 nur in arr2
Also so oder so ähnlich; dass ich eben sehen kann welche gleich und in Ordnung sind, welche nur in arr1 oder arr2 sind und welche vom "Schlüssel" her gleich sind, aber in ihren folge-Inhalt unterschiedlich

Wäre um einen Info oder einen Weg froh...

Grüße Jürgen
Last edited: 2010-07-22 11:42:33 +0200 (CEST)

+5 replies

Gast wer

2010-07-22 12:23

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;

my @arr1 = (
['a', 1, 2, 3],
['b', 4, 4, 3],
['d', 5, 2, 'H'],
);
my @arr2 = (
['a', 1, 2, 3],
['c', 8, 'r', 9],
['d', 5, 'f', 'H'],
);

for my $pos (0..$#arr1)
{
  my $l1=join(':',@{$arr1[$pos]});
  my $l2=join(':',@{$arr2[$pos]});
  if($arr1[$pos][0] eq $arr2[$pos][0])
  {
    if($l1 eq $l2)
    { print "POS: $pos in beiden ok ($l1)\n"; }
    else
    { print "POS: $pos in beiden nicht ok ($l1) <> ($l2)\n" }
  }
  else
  {
    print "POS: $pos: Nur in arr1 ($l1)\n";
    print "POS: $pos: Nur in arr2 ($l2)\n";
  }
}

Last edited: 2010-07-22 12:38:07 +0200 (CEST)

+4 replies

payx

2010-07-22 13:10

User since
2006-05-04
564 Artikel
BenutzerIn

user image

Hallo Jürgen, hallo wer,

diese Lösung ist gut, wenn wirklich nach den Positionen im Array vorgegangen werden soll. Ob das gewünscht ist, geht m.E. aus der Problembeschreibung nicht eindeutig hervor.

Also, z.B. wenn die Arrays jetzt so aussehen würden:

Code (perl): (dl )

my @arr1 = (
['a', 1, 2, 3],
['b', 4, 4, 3],
['d', 5, 2, 'H'],
);
my @arr2 = (
['a', 1, 2, 3],
['d', 5, 'f', 'H'],
['c', 8, 'r', 9],
);

und trotzdem die beiden anonymen Arrays mit dem 'd' an 0-ter Stelle verglichen werden sollten, dann würde es nicht klappen.

Das würde dann nach einer Lösung mit Hashes schreien:

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;

my %hash1 = (
'a' => [1, 2, 3],
'b' => [4, 4, 3],
'd' => [5, 2, 'H'],
);
my %hash2 = (
'a' => [1, 2, 3],
'd' => [5, 'f', 'H'],
'c' => [8, 'r', 9],
);

for my $schluessel (keys %hash1) {
        if ($hash2{$schluessel}) {
                if (join(",", @{$hash1{$schluessel}}) eq join(",", @{$hash2{$schluessel}})) {
                        print "Schluessel $schluessel in beiden ok.\n";
                } else {
                        print "Schluessel $schluessel in beiden nicht ok.\n";
                }
        } else {
                print "Schluessel $schluessel nur in hash1.\n";
        }
}
for my $schluessel (keys %hash2) {
        unless ($hash1{$schluessel}) {
                print "Schluessel $schluessel nur in hash2.\n";
        }
}

Zugegeben, der Vergleich der beiden anonymen Arrays in Zeile 18 ist nicht sehr hübsch.

HTH,
Grüße
payx

//Edit: Alternative für Zeile 18 (einfacher aber auch nicht wirklich hübsch):

Code (perl): (dl )

if ("@{$hash1{$schluessel}}" eq "@{$hash2{$schluessel}}") { ... }

Last edited: 2010-07-22 13:45:33 +0200 (CEST)

+3 replies
Gast DerDieDas

2010-07-22 14:25
ja HoA!
Code: (dl )

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20

#!/usr/bin/perl use strict; use warnings; my %hash1 = ( 'a' => [1, 2, 3], 'b' => [4, 4, 3], 'd' => [5, 2, 'H'], ); my %hash2 = ( 'a' => [1, 2, 3], 'd' => [5, 'f', 'H'], 'c' => [8, 'r', 9], ); while (my ($k,$v1)= each %hash1){ if (my $v2 = $hash2{$k}) { print "$k ungleich" if "@$v1" ne "@$v2" ; } }
das ganze kann aber schief laufen wenn in den Arrayelementen ein Leerzeichen vorkommen darf, da muss man sich noch Gedanken über einen sicheren Trenner machen.
Code: (dl )

1 2 3 4 5 6

while (my ($k,$v1)= each %hash1){ local $"="\0"; if (my $v2= $hash2{$k}) { print "$k ungleich" if "@$v1" ne "@$v2" ; } }
Last edited: 2010-07-22 14:36:59 +0200 (CEST)
- +2 replies
- Gast wieso weshalb warum
  
  2010-07-22 15:21
  
  Wobei natürlich auch join("\0",@$v1) ne join("\0",@$v2) ginge
  Last edited: 2010-07-22 15:28:28 +0200 (CEST)
  - Gast wer nix fragt bleibt ...
    
    2010-07-22 15:32
    natürlich ... und natürlich davon ausgehend das die Daten OK sind, so was wie
    
    Code: (dl )
    
    $hash{x}=undef
    
    oder 0 müsste sonst abgefangen werden.
    
    Last edited: 2010-07-22 15:35:01 +0200 (CEST)

Gast WerWieWas

2010-07-22 12:49

Wenn du schon von eineindeutigem Schlüssel sprichst, wieso benutzt du nicht gleich ein HoA (hash of arrays) statt eines AoA?
Last edited: 2010-07-22 12:56:31 +0200 (CEST)
+2 replies

Gast Juergen

2010-07-22 19:50

Hallo zusammen,

vielen Dank für die in so kurzer Zeit vielen Antworten!
Als Ergänzung: die Reihenfolge des Schlüssels ist nicht gleich, heisst: das "d" kann durchaus in beispielsweise @arr1 auch an erster Stelle stehen, während es in @arr2 an letzter steht.

@guest: HoA: das was ich als "Schlüssel" bezeichne (also die erste "Spalte" im 2d-Array) soll dann der "Key" werden!?

Ich muss mir in aller Ruhe alle eure Lösungen anschauen und versuchen diese zu verstehen.

Bis später.
Grüße Jürgen
Last edited: 2010-07-22 19:53:03 +0200 (CEST)

Gast wer

2010-07-22 20:16

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;

my @arr1 = (
['a', 1, 2, 3],
['b', 4, 4, 3],
['d', 5, 2, 'H'],
);
my @arr2 = (
['a', 1, 2, 3],
['c', 8, 'r', 9],
['d', 5, 'f', 'H'],
);

my %joined;
push(@{$joined{$_->[0]}},{ref=>$_, name=>'array1'}) for(@arr1);
push(@{$joined{$_->[0]}},{ref=>$_, name=>'array2'}) for(@arr2);

for(values(%joined))
{
  if(@$_==1)
  {
    my $lst=join(', ',@{$_->[0]->{ref}});
    print "($lst) nur in $_->[0]->{name}\n";
  }
  else
  {
    my $lst1=join(', ',@{$_->[0]->{ref}});
    my $lst2=join(', ',@{$_->[1]->{ref}});
    if($lst1 eq $lst2)
    { print "In beiden ok ($lst1)\n"; }
    else
    { print "In beiden nicht ok ($lst1) <> ($lst2)\n"; }
  }
}

Last edited: 2010-07-22 20:25:43 +0200 (CEST)

View all threads created 2010-07-22 11:41.