#!/usr/bin/perl
use strict;
use warnings;

my $name_file='names.txt';
my $data_file='data.xml';
my $outp_file='data.out.xml';

# Einlesen der Namenspaare
my %replace;
open(my $nfh, '<', $name_file) or die "error open $name_file $!\n";
while(my $line=<$nfh>)
{
  chomp($line);
  $replace{$1}=$2 if($line=~/^\s*(.+?)\s*=>\s*(.+?)\s*$/);
}
close($nfh);

# erstellen der Suchliste
my $search_str=join('|', map{qr(\Q$_\E)}keys(%replace));
$search_str=qr!($search_str)!;

# daten Datei öffnen
open(my $dfh, '<', $data_file) or die "error open $data_file $!\n";
# Ausgabedatei öffnen
open(my $ofh, '>', $outp_file) or die "error open $outp_file $!\n";
while(<$dfh>)
{
  # Zeile durchsuchen und und Ersetzen
  $_=~s/$search_str/$replace{$1}/g;
  # Zeile ausgeben
  print $ofh $_;
}
close($ofh);
close($dfh);

#!/usr/bin/perl
use strict;
use warnings;
use XML::Twig;

my $name_file='names.txt';
my $data_file='data.xml';
my $outp_file='data.out.xml';

my %replace;
open(my $nfh, '<', $name_file) or die "error open $name_file $!\n";
while(my $line=<$nfh>)
{
  chomp($line);
  $replace{$1}=$2 if($line=~/^\s*(.+?)\s*=>\s*(.+?)\s*$/);
}
close($nfh);

my $twig=XML::Twig->new(
    pretty_print  => 'cvs',
    twig_handlers => {
      _all_ => sub { $_->set_text($replace{$_->text}) if(exists($replace{$_->text})) }
    }
);

$twig->parsefile($data_file);

open(my $ofh, '>', $outp_file) or die "error open $outp_file $!\n";
$twig->print($ofh);
close($ofh);

F_100005.DACA.PV => F_100005.PV

            <ContextItem Type="Trace">
              <Name>F_100005.DACA.PV</Name>
              <ItemDetails xmlns:q4="http://honeywell.context.org/trace" xsi:type="q4:TraceItemDetails" version="1.0">
                <Extensions />
                <q4:TagID>F_100005.DACA.PV</q4:TagID>
                <q4:Color>#0000A0</q4:Color>
                <q4:Marker>square</q4:Marker>
                <q4:Style>Solid</q4:Style>
                <q4:Visible>true</q4:Visible>
                <q4:Selected>false</q4:Selected>
                <q4:TimeOffset>0S</q4:TimeOffset>
                <q4:XAxis>false</q4:XAxis>
                <q4:YAxis>false</q4:YAxis>
                <q4:Minimum>0</q4:Minimum>
                <q4:Maximum>100</q4:Maximum>
                <q4:YRange>Auto</q4:YRange>
                <q4:YCustomMaximum>0</q4:YCustomMaximum>
                <q4:YCustomMinimum>0</q4:YCustomMinimum>
                <q4:HistogramPlot>false</q4:HistogramPlot>
                <q4:UseSecondaryXAxes>false</q4:UseSecondaryXAxes>
                <q4:Interpolation>Default</q4:Interpolation>
              </ItemDetails>
              <ItemCollection>
                <ContextItem Type="Tag">
                  <Name>F_100005.DACA.PV</Name>
                  <ItemDetails xmlns:q5="http://honeywell.context.org/tag" xsi:type="q5:TagItemDetails" version="1.0">
                    <Extensions />
                    <q5:ItemName>F_100005.DACA.PV</q5:ItemName>
                    <q5:Enumerated>false</q5:Enumerated>
                    <q5:MinimumConfidence>0</q5:MinimumConfidence>
                    <q5:NullValueReplacement>######</q5:NullValueReplacement>
                    <q5:Units />
                  </ItemDetails>
                  <ItemCollection>
                    <ContextItem Type="DataSource">
                      <Name>DefaultPHD</Name>
                      <ItemDetails xmlns:q6="http://honeywell.context.org/datasource" xsi:type="q6:DataSourceItemDetails" version="1.0">
                        <Extensions />
                        <q6:Name>DefaultPHD</q6:Name>
                        <q6:Type>PHD</q6:Type>
                        <q6:ServerName>PHD_HOST</q6:ServerName>
                        <q6:ServerPort>-1</q6:ServerPort>
                        <q6:BrowseServerName>PHD_HOST</q6:BrowseServerName>
                        <q6:BrowseServerPort>-1</q6:BrowseServerPort>
                      </ItemDetails>
                      <ItemCollection />
                    </ContextItem>
                  </ItemCollection>
                </ContextItem>
              </ItemCollection>
            </ContextItem>