GUI in Form von Windows Explorer erstellen (Graphische Oberflächen)

[thread]15577[/thread]

GUI in Form von Windows Explorer erstellen

Leser: 29

Articles: hide open all | hide show old branches

+16 replies

Gast Mampfgnom

2010-10-27 15:05

Hallo.

Unter dem Suchbegriff "Explorer" habe ich leider nichts passendes gefunden, weshalb ich jetzt einen eigenen thread erstelle.

Ich möchte gerne eine GUI erzeugen, die die Form des Windows Explorer besitzt, d.h. links ist ein Verzeichnisbaum, rechts der Inhalt des aktuell im Verzeichnisbaum ausgewählten Verzeichnisses und oben eine Menüleiste.

Meine Idee ist nun, den Verzeichnisbaum über einen DirTree dazustellen und das Menü über ein MenuBar. Wie kann ich allerdings das rechte Fenster realisieren? Mir fehlt dazu leider jede Idee, weil ich auch nicht so viele widgets kenne. Oder gibt es ein komplett fertiges widget was meine Wünsche erfüllt?

Grüße,

Niels
Last edited: 2010-10-27 15:22:06 +0200 (CEST)

#Kein Kommentar

2010-10-27 15:46

User since
2007-06-09
575 Artikel
HausmeisterIn

soviel ich das weiß, gibt es das nicht, zumindest je nachdem was für anforderungen du hast.

willst du nur eine reine liste, in der ein kleines icon erscheint und in spalten jeweils dateinname, -größe, -typ, etc. dargestellt sind, dann könntest du Tk::HList nehmen, das würde perfekt für diese aufgabe passen.

oder willst ein interaktives feld mit symbolen (unter dem explorer unter der ansicht <Symbole> zu finden), bei denen du das icon mit dem dateinamen im fenster hin und her verschieben und so deren sortierung verändern kannst? dafür gibt es meines wissens nach kein fertiges widget, aber so etwas könnte man mit Tk::Canvas angehen.
Gerade weil wir alle in einem Boot sitzen, sollten wir froh sein, dass nicht alle auf unserer Seite sind
+14 replies

leo11

2010-10-27 16:40

User since
2008-08-14
250 Artikel
BenutzerIn
[default_avatar]

Ich hab gerad mal nach Beispielen in einigen Büchern geschaut. Leider hab ich nichts gefunden. Deine Frage erinnert mich an dieses Java-Bsp: JTree/Table

Vielleicht hilft das konzeptionell weiter, oder bringt den ein oder anderen auf eine Idee.

+13 replies

Gast Mampfgnom

2010-10-28 08:16

Hallo und danke erst mal für die Antworten.

@leo11: so einen TreeTable meine ich nicht, aber danke für die Idee.

@erste Antwort: Was genau meinst du mit interaktiv? Icons brauche ich nicht und hin und herziehen will ich auch nichts können. Ich hätte rechts in dem Fenster einfach nur gerne den Inhalt des links ausgewählten Verzeichnisses, also alle enthaltenen Ordner und Dateien. Schön wäre es auch, falls rechts ein Ordner zu sehen ist, ich auf den klicken könnte, und danach rechts der Inhalt des eben gerade angeklickten Ordners zu sehen ist.
Ich werde mir mal HList anschauen und mich noch mal melden, wenn ich nicht weiterkomme.

Grüße,

Mampfgnom
Last edited: 2010-10-28 09:15:38 +0200 (CEST)

+12 replies

Gast Mampfgnom

2010-10-28 10:13

So mittlerweile habe ich einen groben Plan wie ich vorgehen kann. Zum Testen habe ich mir erst mal nur eine HList erstellt und will in dieser durch die Ordner navigieren können, d.h. klicke ich in der HList auf einen Eintrag, wird die ganze HList gelöscht und mit dem neuen Ordnerinhalt gefüllt. Ich hänge zur Zeit allerdings beim Löschen der HList:

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;
use Tk;
use Tk::HList;
use Tk::ItemStyle;
use Cwd;

my $mw = MainWindow->new();
$mw->geometry("400x600");

chdir "..";
my $cwd = getcwd;

my $hlist = $mw->HList(-columns=>2,
                                                          -command=>\&neues_verzeichnis($cwd)           # die Zeile wird noch so angepasst, dass das neue Verzeichnis übergeben wird
                                                        )->pack(-expand=>1, -fill=>'both');

my $red  = $hlist->ItemStyle('text', -foreground=>'#800000');

&neues_verzeichnis($cwd,$hlist);

Tk::MainLoop;

sub neues_verzeichnis{
        my @inhalt;
        my $e;
        opendir(DIR, $_[0]);
        while (my $tmp = readdir(DIR)) {
                push(@inhalt,$tmp);
        };
        $hlist->deleteAll;      
        foreach (sort(@inhalt)) {
            $e = $hlist->addchild("");
            $hlist->itemCreate($e, 0, -itemtype=>'text',
                     -text=>$_, -style=>$red );
        }
}

Er bringt mir den Fehler:

Can't call method "deleteAll" on an undefined value at test.pl line 31.

Ich habe die HList auch schon als Argument an die Sub übergeben und alle möglichen gloablen und lokalen Definitionen durchprobiert, aber nichts hat geholfen. Kann mir bitte jemand sagen worauf sich das "undefined value" bezieht und wo meni Fehler liegt?

Danke,

Niels
Last edited: 2010-10-28 10:18:45 +0200 (CEST)

+11 replies

Gast Mampfgnom

2010-10-28 12:36

So ich habe mal weiter gespielt und mittlerweile funktioniert das Löschen auch, keine Ahnung warum.
Mein Problem jetzt ist allerdings, dass ich zwar durch Verzeichnisse navigieren kann, aber erstens nur Ordner angezeigt werden und zweitens davon nicht alle. Hat jemand eine Ahnung woran das liegen kann?

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;
use Tk;
use Tk::HList;
use Tk::ItemStyle;
use Cwd;

my $mw = MainWindow->new();
$mw->geometry("400x600");

chdir "..";
my $cwd = getcwd;

my $hlist = $mw->HList(-columns=>2,-itemtype   => 'text',
                                                          -command=>sub{&doppelklick;}
                                                        )->pack(-expand=>1, -fill=>'both');

&neues_verzeichnis($cwd);

MainLoop;

sub doppelklick{
        my $path = join "\n", $hlist->infoSelection();
   my $cwd = getcwd;
   chdir "$cwd/$path";
   $cwd = getcwd;
   print "\n$cwd";
   &neues_verzeichnis($cwd);
}

sub neues_verzeichnis{
        my @inhalt;
        opendir(DIR, $_[0]);
        while (my $tmp = readdir(DIR)) {
                push(@inhalt,$tmp);
        };
        closedir DIR;   
        $hlist->deleteAll;      
        foreach (sort(@inhalt)) {
                $hlist->add("$_", -text=>$_);
        }
}

Last edited: 2010-10-28 12:40:40 +0200 (CEST)

+10 replies

Molaf

2010-10-28 13:59

User since
2007-10-11
119 Artikel
BenutzerIn
[default_avatar]

Hallo,

Code (perl): (dl )

1
2
3

while (my $tmp = readdir(DIR)) {
                push(@inhalt,$tmp);
        };

läßt sich verkürzen durch

Code (perl): (dl )

my @inhalt = readdir(DIR);

ansonsten läuft Dein Programm bei mir nicht, das HList->add schlägt fehl.

Gast Mampfgnom

2010-10-28 14:09

Danke für den Tipp mit der Verkürzung.

Bringt er bei dir eine Fehlermeldung, wenn das Skript abstürzt? Und siehst du überhaupt die erste HList? Ich erhalte nämlich Warnungen, wenn ich in der HList Doppelklicke. Komischerweise erfüllt das Programm trotzdem seine Funktion.
Last edited: 2010-10-28 14:16:29 +0200 (CEST)
+8 replies

Gast Mampfgnom

2010-10-28 14:19

Ich hoffe, es ist okay wenn ich immer mal einen Zwischenstand reingebe. Sollte das unter SPAM fallen, kann mir das ein Moderator ruhig sagen.

Jedenfalls: großer Zauber. Der Fehler liegt im Separator. Dieser ist standardmäßig bei der HList der Punkt "." . Jedes mal wenn mein Skript also eine Datei mit *.Suffix findet, kriegt er irgendwelche Probleme mit der HList. Ich habe jetzt einfach beim Erstellen der HList die Option: -separator=> "/" eingefügt und schon geht es. Warum das Skript bei dir nicht startet Molaf, weiß ich allerdings nicht.
Last edited: 2010-10-28 14:22:37 +0200 (CEST)

+7 replies

Molaf

2010-10-28 14:42

User since
2007-10-11
119 Artikel
BenutzerIn
[default_avatar]

Mit dem Seperator funktioniert es jetzt bei mir auch. Das sind aber die ganz gewöhnlichen Startschwierigkeiten mit HList, die ich auch immer habe...

Warnungen kommen auch nicht mehr und Dateien wie Ordner werden gemeinsam gezeigt.

+6 replies

Gast Mampfgnom

2010-10-29 08:40

Guten Morgen.

Jetzt habe ich wirklich mal ein grafisches Problem. Warum auch immer will mir Perl meine Widgets nicht so anordnen wie ich will. Zur Erinnerung . . . oben Menüleiste, darunter ein Labentry und darunter 2 gleich große Bereiche nebeneinander. Die 2 Bereiche will ich erst mal durch Frames abgrenzen, allerdings hängt es hier schon. Perl ordnert mir die Frames irgend wie an. Findet von euch einer bei mir einen Fehler?

Code (perl): (dl )

#!/usr/bin/perl

use Tk;
use Tk::LabEntry;
use Tk::DirTree;
use Tk::HList;
use Cwd;
#use pam_aba_103_17;
#use pam_aba_24_10;


my $mw = MainWindow->new(-title=>"PAM_ABA v1.7");                                                                               # MainWindow
my $width = $mw->screenwidth;
my $height = $mw->screenheight;
$mw->geometry($width.'x'.$height);

$mw->configure(-menu => my $menubar = $mw->Menu);                                                                               # Menüleiste
my $materialtyp = $menubar->cascade(-label => '~Materialtyp', -tearoff=>0);
#$menubar->command(-command=>\&konvertieren, -label=>"~Konvertieren");
#$menubar->command(-command=>\&verzeichnis, -label=>"~Verzeichnis");
$menubar->command(-command=>sub{exit}, -label=>"~Beenden");

@typ = ("SHE 103", "SOL 24");                                                                                                                                   # Materialtypen
$i=0;
foreach $typ (@typ){
        $i++;
        $materialtyp->radiobutton(-label=>$typ, -variable=>\$rb, -value=>$i);
}
$rb = 1;

$frame_hintergrund = $mw->Frame(-bg=>'green')->pack(-fill=>'both', -expand=>1);

$frame0 = $frame_hintergrund->Frame(-height=>30, -bg=>'blue')->pack(-side=>'top', -expand=>1, -fill=>'x', -anchor=>'n');
#chdir("../Materialverzeichnis");
$pfad_mat = getcwd();
$LE = $frame0->LabEntry(-label=>"Abaqus Materialverzeichnis",
                                  -labelPack=>[-side=>'right'], -width=>80,
                                  -text=>"$pfad_mat")->pack(-padx=>20, -pady=>5);
                                  
$frame1 = $frame_hintergrund->Frame(-width=>int($width/2), -bg=> 'red')
                                        ->pack(-side=>'left', -fill=>'y',-expand=>1);
$frame2 = $frame_hintergrund->Frame(-width=>int($width/2), -bg=> 'yellow')
                                        ->pack(-expand=>1, -fill=>'y', -side=>'right', -anchor=>'e');
                                        
$DIR_TREE = $frame2->Scrolled('DirTree',
                            -scrollbars => "osoe",
                            -width => 30,
                            -height => 25,
                            -exportselection => 1,
                            -browsecmd => sub {$cwd = shift},
                            -command   => \&callback)
                            ->pack(-fill => "both", -expand => 1);

Last edited: 2010-10-29 08:54:40 +0200 (CEST)

Gast AndiE

2010-10-29 21:19

Hallo,

der Fehler liegt daran, das ein Frame nur EIN Element aufnehmen kann. Versuche es mal mit "TK:Grid".

Last edited: 2010-10-29 21:31:08 +0200 (CEST)
+4 replies

pktm

2010-10-29 23:30

User since
2003-08-07
2921 Artikel
BenutzerIn

Hallo!

Nimm ein Frame, das die beiden Frames, die gleich groß sein sollen, aufnimmt.

Ich baue Progarmme nach Möglichkeit immer in Zeilen auf, damit ich für jede Zeile ein eigenes Frame habe.

Hier das Minimalbeispiel:

Code: (dl )

#!/usr/bin/perl

use strict;
use warnings;
use Tk;

my $mw = tkinit();

my $parent_frame = $mw->Frame()->pack(-fill => 'both', -expand => 1,);

my $left = $parent_frame->Frame(-bg => 'red')->pack(-side => 'left', -fill => 'x', -expand => 1,);
$left->Button(-text => 'test',)->pack();

my $right = $parent_frame->Frame(-bg => 'blue')->pack(-side => 'left', -fill => 'x', -expand => 1,);
$right->Button(-text => 'test',)->pack();

$mw->MainLoop();

Und hier ein anderer Ansatz, mit den verschiedenen Zeilen, einem Menu und deinem LabEntry. Da könntest du ganz gut weiter machen :)

Code: (dl )

#!/usr/bin/perl

package TkApp;

use base qw(Class::Accessor);

use strict;
use warnings;
use FileHandle;
use Data::Dumper qw/Dumper/;
use Date::Format;
use Tk;
use Tk::LabEntry;
use Tk::DirTree;
use Tk::HList;

__PACKAGE__->follow_best_practice();
__PACKAGE__->mk_accessors(qw(mw graph));

our $VERSION = 0.1;

=head1 NAME

TkApp - experimental layout

=head1 SYNOPSIS

	use strict;
	use warnings;
	
	my $app = TkApp->new();
	$app->run();

=head1 DESCRIPTION

- menu
- entry box
- two areas with equal size

=head2 EXPORT

None by default.


=head1 METHODS

=head2 new()

Ctor. Calls _build_gui.

=cut

sub new {
	my $class = shift;
	
	my $self = bless({}, $class);
	
	my $mw = Tk::MainWindow->new();
	$self->set_mw($mw);
	
	$self->_build_gui();
	
	return $self;
} # /new




=head2 _build_gui()

Build GUI. Set up widgets etc. Positioning is done here, too.

Private method. Don't call it directly, as this will be done by new().

=cut

sub _build_gui {
	my $self = shift;
	my $mw = $self->get_mw();
	my %gui = ();

	# -- menu
	my $menuitems = [
		[Cascade => "~File", -menuitems =>
			[
				[Button => "Some ~Method", -command => sub{
					return $self->some_method();
				}],
				[Separator => ""],
				[Button => "~Exit", -command => sub{ exit(0); }],
			],
		],
	];
	my $menu = $mw->Menu(-menuitems => $menuitems);
	$mw->configure(-menu => $menu);


	# define & pack your widgets here
	$gui{f_selectors} = $mw->Frame(-bg => 'green')->pack(-fill => 'x');
	$gui{f_selectors}->LabEntry(
		-label=>"Abaqus Materialverzeichnis",
		-labelPack=>[-side=>'right'], -width=>80,
		-text => 'TODO: initial value',
	)->pack(-padx => 20, -pady => 5);
	
	$gui{f_row2} = $mw->Frame(
		-bg => 'yellow'
	)->pack(-fill => 'both', -expand => 1,);
	
	$gui{f_left} = $gui{f_row2}->Frame(
		-bg => 'red',
	)->pack( -side => 'left', -fill => 'both', -expand => 1, );
	
	$gui{f_left}->Label(-text => 'test')->pack();
	
	$gui{f_right} = $gui{f_row2}->Frame(
		-bg => 'blue',
	)->pack( -side => 'right', -fill => 'both', -expand => 1, );
	
} # /_build_gui




=head2 run()

This actually starts the application, including the gui event loop.

=cut

sub run {
	my $self = shift;
	my $mw = $self->get_mw();
	
	$mw->MainLoop();
} # /run




=head1 SEE ALSO

Inspired by a thread at L<http://www.perl-community.de>.

=head1 AUTHOR

todo

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2010 by todo

This library is free software; you can redistribute it and/or modify it under
the same terms as Perl itself, either Perl version 5.8.8 or, at your option,
any later version of Perl 5 you may have available.

=cut

1;

use strict;
use warnings;

my $app = TkApp->new();
$app->run();

http://www.intergastro-service.de (mein erstes CMS :) )

+3 replies

Gast Mampfgnom

2010-11-01 09:44

Hallo und danke für die Antworten.

@pktm: Ich habe doch auch ein parent Frame verwendet ($frame_hintergrund), aber trotzdem hat er mir die anderen Frames ganz putzig angeordnet. Mittlerweile habe ich das Problem mit place umgangen. Gefällt mir zwar nicht ganz so gut die Lösung, aber es erfüllt seinen Zweck. Hier mal mein Aktueller Stand in gekürzter Fassung:

Code (perl): (dl )

#!/usr/bin/perl

use Tk;
use Tk::LabEntry;
use Tk::DirTree;
use Tk::HList;
use Cwd;

my $mw = MainWindow->new(-title=>"PAM_ABA v1.8");                                                                               # MainWindow
my $width = $mw->screenwidth;
my $height = $mw->screenheight;
$mw->geometry($width.'x'.$height);

$mw->configure(-menu => my $menubar = $mw->Menu);                                                                               # Menüleiste
my $materialtyp = $menubar->cascade(-label => '~Materialtyp', -tearoff=>0);
$menubar->command(-command=>\&konvertieren, -label=>"~Konvertieren");
#$menubar->command(-command=>\&verzeichnis, -label=>"~Verzeichnis");
$menubar->command(-command=>sub{exit}, -label=>"~Beenden");

@typ = ("SHE 103", "SOL 24");                                                                                                                                   # Materialtypen
$i=0;
foreach $typ (@typ){
        $i++;
        $materialtyp->radiobutton(-label=>$typ, -variable=>\$rb, -value=>$i, -command=>\&label_anpassen);
}
$rb = 1;

$frame0 = $mw->Frame(-height=>30)->pack(-expand=>1, -fill=>'x', -anchor=>'n');
$cwd = getcwd;
$pfad_mat = getcwd();
$label_typ = $frame0->Label(-text=>"Typ: SHE 103")->place(-x=>0, -y=>0, -relheight=>1);
$entry = $frame0->Entry(-width=>120, -text=>"$pfad_mat")->place(-x=>200, -y=>0, -relwidth=>2/3, -relheight=>1);
$check = $frame0->Checkbutton(-text=>"Materialverzeichnis auswaehlen", -variable=>\$cb_value)->place(-x=>1300, -y=>0, -relheight=>1);
$cb_value = 1;

$frame_hintergrund = $mw->Frame->place(-x=>0, -y=>30, -relheight=>110/113, -relwidth=>1);
$frame1 = $frame_hintergrund->Frame(-width=>int($width/3), -bg=> 'red')
                                        ->place(-x=>0,-y=>0, -relwidth=>1/3, -relheight=>1);
$frame2 = $frame_hintergrund->Frame(-width=>int($width*2/3), -bg=> 'yellow')
                                        ->pack(-expand=>1, -fill=>'y', -side=>'right', -anchor=>'e');
                                        
$DIR_TREE = $frame1->Scrolled('DirTree', -scrollbars => "osoe", -width => 30,
                            -height => 25, -exportselection => 1, -browsecmd => sub {$pfad_mat = shift;&neues_verzeichnis($pfad_mat);},
                            -command   => \&callback)->place(-x=>0, -y=>0, -relwidth=>1, -relheight=>1);

my $hlist = $frame2->Scrolled('HList', -scrollbars=>'oe', -columns=>1,-itemtype   => 'text',-separator=>"/",
                                                                 -selectmode=>'extended', -header=>1, -command=>sub{&doppelklick;}
                                                                )->place(-x=>0, -y=>0, -relwidth=>1, -relheight=>1);
$hlist->header('create',0);
$hlist->header('configure',0,-text=>"PAM CRASH Materialkarte (*.mat) auswaehlen; Mehrfachauswahl moeglich");                                                            

&neues_verzeichnis($pfad_mat);

MainLoop;

sub konvertieren{
        print "\nBlubb" x10;
}

sub callback{
        $entry->configure(-textvariable=>$pfad_mat) if ($cb_value == 1);
}

sub doppelklick{
        my $path = join "\n", $hlist->infoSelection();
   my $pfad_mat = getcwd;
   chdir "$pfad_mat/$path";
   $pfad_mat = getcwd;
   &callback;
   &neues_verzeichnis($pfad_mat);
}

sub neues_verzeichnis{
        opendir(DIR, $_[0]);
        my @inhalt = readdir(DIR);
        closedir DIR;   
        $hlist->deleteAll;      
        foreach (sort(@inhalt)) {
                $hlist->add("$_", -text=>$_);
        }
}

sub label_anpassen{
        $label_typ->configure(-text=>"Typ: $typ[$rb-1]");
}

Könnt ihr ja mal ausprobieren und sagen, ob es bei euch funktioniert.

AndiE

2010-11-01 15:59

User since
2010-10-24
65 Artikel
BenutzerIn

Hallo,

ich habe auch ein bisschen rumexperimentiert. Ich denke, dass der Schlüssel für die Darstellung im Algorthmus liegt, der auf der "man"-page von "Tk::pack" (auf englisch) erläutert ist.

Aber bisher habe ich noch keine deutsche Übersetzung gefunden. -Muß ich wohl selbst machen :-)

Schöne Grüße
Andre
Last edited: 2010-11-01 16:21:30 +0100 (CET)
pktm

2010-11-01 22:45
User since
2003-08-07
2921 Artikel
BenutzerIn
Hi!

Ich meine, Gast AndiE hat das schon geschrieben.
Mein Frame hat nur genau 2 Kinder. Eins links und eins rechts.
Dein Ansatz erzeugt das LabEntry *und* die beiden nachfolgenden Frames im selben Frame.

Außerdem hast du das 2. Frame mit side => 'right' ausgerichtet, -side => 'left' bringts aber. Siehe dazu mein Mini-Beispiel.

Dein Code:
Code: (dl )

1 2 3 4 5 6

$frame_hintergrund = $mw->Frame(-bg=>'green')->pack(-fill=>'both', -expand=>1); $frame0 = $frame_hintergrund->Frame()->pack(-side=>'top', -expand=>1, -fill=>'x', -anchor=>'n'); $LE = $frame0->LabEntry()->pack(); $frame1 = $frame_hintergrund->Frame()->pack(-side=>'left', -fill=>'y',-expand=>1); $frame2 = $frame_hintergrund->Frame()->pack(-expand=>1, -fill=>'y', -side=>'right', -anchor=>'e');
$frame_hintergrund bekommt 3 Kinder: Das Frame für das LabelEntry + die beiden anderen.

Btw, jetzt strict lernen erspart die 'ne Menge Arbeit beim Fehlersuchen ;)
Ich hab am Anfang auch etwas gezögert, will es aber nicht mehr missen.

hth, pktm
http://www.intergastro-service.de (mein erstes CMS :) )

View all threads created 2010-10-27 15:05.