Logfile abarbeiten, brauche Denkanstoß (gelöst) (Allgemeines zu Perl)

[thread]15647[/thread]

Logfile abarbeiten, brauche Denkanstoß [gelöst]

Leser: 17

Articles: hide open all | hide show old branches

+7 replies

Gast FlorianL

2010-11-19 11:59

Hallo!
Ich möchte das Logfile eines Gameservers von einem Script durchlaufen lassen, wenn es auf ein 'Badword' trifft soll es die Zeile ausgeben...

So sieht das Log aus:

Code: (dl )

2010-11-18 22:52:40 [INFO] Sign placed by Shanuson at 335 65 -1638
2010-11-18 22:52:40 [INFO] Line 1 : You are
2010-11-18 22:52:40 [INFO] Line 2 : a
2010-11-18 22:52:40 [INFO] Line 3 : stupid
2010-11-18 22:52:40 [INFO] Line 4 : Asshole
2010-11-18 22:57:45 [INFO] Sign placed by Shanuson at 396 65 -1612
2010-11-18 22:57:45 [INFO] Line 1 : Bridge
2010-11-18 22:57:45 [INFO] Line 2 : Under
2010-11-18 22:57:45 [INFO] Line 3 : Construction
2010-11-18 22:57:45 [INFO] Line 4 : Shanuson

Code (perl): (dl )

#!/usr/bin/perl
# Minecraft Audit
#   by m1ndgames for
#     Hexagon.de.tf
#############################
use warnings;
use strict;
my $logfilepath = "/minecraft/bin/logs/";
my @logfiles = `ls $logfilepath*.log`;
open(BADWORDS, "<", "badwords.db");


foreach(@logfiles) {
        open(CURRENTLOG, $_) or die $!;
        foreach(<CURRENTLOG>) {
                my $line = $_;
                if ($line =~ /Sign/) {
                        print $line;
                } elsif ($line =~ /Line/) {
                        foreach (<BADWORDS>) {
                                if ($line =~ /$_/) {
                                        print $_;
                                }
                        }
                } elsif ($line =~ /Antigrief/) {
#                       print $line;
                }
        }
}

So, das funktioniert ja auch prima... aber ganz ohne den übeltäter ists ja sinnlos, also meine frage ist: Wie kann ich die Zeile über dem Regex ausgeben lassen, aber nur falls diese auch greift? Ich hab überlegt erstmal alles in ein array zu pushen, falls kein badword folgt lösche ich wieder (Wär aber auch mist wegen den 4 zeilen die ich prüfen muss, oder?), und am schluss lass ich mir das ganze array nochmal anzeigen...

habt ihr ne bessere idee?
Last edited: 2010-11-19 12:12:06 +0100 (CET)

Gast FlorianL

2010-11-19 12:16
Bin nicht sicher ob das klar verständlich war und editieren kann ich als Gast nicht :D

also die Ausgabe wünsche ich mir in etwa so:
Code: (dl )

1 2

2010-11-18 22:52:40 [INFO] Sign placed by Shanuson at 335 65 -1638 2010-11-18 22:52:40 [INFO] Line 4 : Asshole
Last edited: 2010-11-19 12:35:48 +0100 (CET)
+5 replies

topeg

2010-11-19 12:31

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

Das ganze hat Fehler.

Code (perl): (dl )

foreach (<BADWORDS>) {
                                if ($line =~ /$_/) {
                                        print $_;
                                }
                        }

Das wird nur einmal durchlaufen, wenn die Datei "badwords.db" vollständig gelesen ist, wird die Schleife nicht mehr ausgeführt. Weiterhin wird unter Umständen eine Zeile mehrfach ausgeben, wenn in einer Zeile mehrere Wörter, die auf der Suchliste stehen vorkommen.

Ich habe das mal kurz etwas umgeschrieben:

Code (perl): (dl )

#!/usr/bin/perl
use warnings;
use strict;
use FindBin '$Bin';

my $wordsfile="$Bin/badwords.db";
my $logfilepath = "/minecraft/bin/logs/";
my @logfiles = glob("$logfilepath*.log");

open(my $fh, '<', $wordsfile) or die("Error open $wordsfile ($!)");
my @barwords=<$fh>;
close($fh);
chomp(@barwords);

for my $file (@logfiles)
{
  open(my $fh, '<', $file) or die ("Error open $file ($!)");
  while(my $line=<$fh>)
  {
    if($line=~/Sign|Antigrief/)
    { print $line; }
    elsif($line=~/Line/ && grep{$line=~/$_/}@barwords)
    { print $line; }
  }
}

+4 replies

clms

2010-11-19 12:53

User since
2010-08-29
373 Artikel
BenutzerIn
[default_avatar]

So wie ich es verstanden habe, soll "Sign" nur ausgegeben werden,
wenn anschließend auch ein Badword gefunden wurde.
Dafür würde ich das Innere der while-Schleife anpassen:

Code (perl): (dl )

while(my $line=<$fh>) {
  my $sign = '';
  if ($line=~/Sign|Antigrief/) { 
    $sign = $line; 
  } elsif ($line=~/Line/ && grep {$line=~/$_/} @barwords) {
    if ($sign) {
      print $sign;
      $sign = '';
    }
    print $line; 
  }
}

+3 replies

topeg

2010-11-19 13:08

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

Wenn das so sein soll, muss "$sign" aber außerhalb der Schleife definiert werden:

Code (perl): (dl )

my $sign = '';
while(my $line=<$fh>) {
  if ($line=~/Sign|Antigrief/) { 
    $sign = $line; 
  } elsif ($line=~/Line/ && grep {$line=~/$_/} @barwords) {
    if ($sign) {
      print $sign;
      $sign = '';
    }
    print $line;
  }
}

Last edited: 2010-11-19 13:09:53 +0100 (CET)

Gast FlorianL

2010-11-19 14:04

Danke für die Hilfe :)

Ich habs jetzt so gelöst:

Code (perl): (dl )

#!/usr/bin/perl
# Minecraft Logfile Audit
#     by m1ndgames for
#      Hexagon.de.tf
#############################
use warnings;
use strict;
use FindBin '$Bin';

my @staff = ("m1ndgames", "Hexzel");

my $badwordsfile = "$Bin/badwords.db";
my $logfilepath  = "/minecraft/bin/logs/";
my @logfiles     = glob("$logfilepath*.log");

open( my $fh, '<', $badwordsfile ) or die("Error open $badwordsfile ($!)");
my @badwords = <$fh>;
close($fh);
chomp(@badwords);

my @signreport;
my @griefreport;

for my $file (@logfiles) {
    open( my $fh, '<', $file ) or die("Error open $file ($!)");
    my @logs = <$fh>;
    close($fh);
    foreach ( @logs ) {
        my $line = $_;
        if ( $line =~ /Line/ && grep { $line =~ /$_/ } @badwords ) {
            my $badline = $line;
            if ($badline =~ /(.+) \[INFO\] Line . : (.+)/) {
                my $date = $1;
                my $sign = $2;
                foreach ( @logs ) {
                        if ($_ =~ /$date \[INFO\] Sign placed by (.+) at (.+)/) {
                                push(@signreport,"$date - $1 placed Sign \"$sign\" at location: $2\n");
                        }
                }
            }
        } elsif ($line  =~ /(.+) \[INFO\] Antigrief incident coordinates : (.+)/) {
                my $date = $1;
                my $location = $2;
                foreach ( @logs ) {
                        if ($_ =~ /$date \[INFO\] Antigrief alarm : (.+)/) {
                                push(@griefreport,"$date - Grief Alarm: $1 - Coordinates: $location\n");
                        }
                }
        }
    }
}

foreach(@signreport) {
        my $line = $_;
        if (grep  { $line =~ /$_/ } @staff ) {
                shift;
        } else {
                print $_;
        }
}

foreach(@griefreport) {
        my $line = $_;
        if (grep  { $line =~ /$_/ } @staff ) {
                shift;
        } else {
                print $_;
        }
}

Kann man sicherlich besser machen, aber es läuft ;)
Last edited: 2010-11-19 14:10:39 +0100 (CET)

clms

2010-11-19 16:12

User since
2010-08-29
373 Artikel
BenutzerIn

2010-11-19T12:08:06 topeg
Wenn das so sein soll, muss "$sign" aber außerhalb der Schleife definiert werden:
Klar!

Ich hatte mir bei der ersten Analyse der Aufgabe gemerkt,
dass es innerhalb der for-Schleife definert werden sollte.
Beim Schreiben der Antwort ist das entscheidende "for" dann in Vergessenheit geraten.

View all threads created 2010-11-19 11:59.