[Tk] Referenz auf Tk Objekt (Graphische Oberflächen)

[thread]17186[/thread]

[Tk] Referenz auf Tk Objekt

Tags: perl5 GUI Tk Similar Threads

Readers: 12

Articles: hide open all | hide show old branches

+5 replies

Kean

2012-02-23 14:12

User since
2004-08-18
463 articles
BenutzerIn

user image

Kann ich eine Referenz auf ein Tk Objekt erzeugen und dann Methoden darauf anwenden?

So in etwa:

Code (perl): (dl )

my $hlist = $mw->Scrolled( "HList",
                         -header => 1,
                         -columns => 2,
                       )->pack();
my $hlist_ref = \$hlist;
$hlist_ref->delete('all');

+4 replies

2012-02-23 14:21

User since
2003-08-04
12208 articles
Admin1

generell ist ein objekt immer schon eine referenz. wenn du eine referenz auf eine referenz erstellen willst, dann musst du diese zuerst dereferenzieren, bevor du was drauf anwendest.
$$hlist_ref->...

aber wie gesagt, normalerweise brauchst du gar keine referenz.

Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live. -- Damian Conway in "Perl Best Practices"
lesen: Wiki:

Wie frage ich & perlintro Wiki:

brian's Leitfaden für jedes Perl-Problem

Kean

2012-02-23 14:27

User since
2004-08-18
463 articles
BenutzerIn

Ich kann mir gut vorstellen, dass mein generelles Problem woanderst liegt.
Genau genommen habe ich eine Tk Anwendung mit einem Frame und in diesem Frame mehrere Tk-Hlist und Tk-Text Objekte. Dazu gibt es noch ein paar Funktionen, welche auf die Objekte zugreifen und z.b. Daten laden.

Jetzt möchte ich dieses Gerüst gerne mehrfach erzeugen und getrennt voneinander nutzen ohne die Objekte und Funktionen jeweils einfach per copy and paste zu kopieren.

Ist das irgendwie möglich oder müsste ich dafür den ganzen Aufbau Objekt orientiert machen?
+2 replies

Kean

2012-02-23 14:55

User since
2004-08-18
463 articles
BenutzerIn

user image

Hier mal ein Minimalbeispiel von meinem Programm (anstatt mit Hlist/Text mit Entry):

Code (perl): (dl )

use strict;
use warnings;
use Tk;

my $mw = MainWindow->new();

my $frame = $mw->Frame()->pack;

my $name = $frame->Entry( )->pack;
my $alter = $frame->Entry( )->pack;

my $button = $frame->Button( -text => "Ausgabe",
                                                         -command => \&ausgabe,
                           )->pack;                                                

MainLoop;

sub ausgabe
{
print $name->get()." ".$alter->get()."\n";
}

Und dies würde ich gerne so "umschreiben", dass der Frame mit den beiden Entrys in einer Funktion erzeugt werden und die Funktion ausgabe nur einmal benötigt wird.

pktm

2012-02-23 15:54

User since
2003-08-07
2921 articles
BenutzerIn

Meinst du sowas hier?

Code (perl): (dl )

use strict;
use warnings;
use Tk;

my $mw = MainWindow->new();

my $itemhref = build_widgets($mw);

$mw->MainLoop();
exit(0);


sub build_widgets {
        my $toplevel = shift or die('Missing toplevel widget');
        
        my $frame = $toplevel->Frame()->pack;
        my $name = $frame->Entry( )->pack;
        my $alter = $frame->Entry( )->pack;
        my $button = $frame->Button(
                -text => "Ausgabe",
                #-command => \&ausgabe,
        )->pack;

        my %map = (
                toplevel => $toplevel,
                frame => $frame,
                name => $name,
                alter => $alter,
                button => $button,
        );

        $button->configure(-command => sub{ ausgabe(\%map); return 1; });
        
        return \%map;
} # /build_widgets

sub ausgabe {
        my $itemhref = shift or die('Missing widget href');
        print $itemhref->{name}->get()." ". $itemhref->{alter}->get()."\n";
} # /ausgabe

Das kann man auch so umschreiben, dass die Sub als Argument übergeben wird.
Aber so besonder weit weg von einer Klasse ist das auch nicht mehr:

Code (perl): (dl )

#!perl

package MyWidget;

use strict;
use warnings;
use Tk;

sub new {
        my $class = shift;
        my $toplevel = shift or die('Missing toplevel');
        
        my $self = bless({}, $class);
        $self->{todo_class_accessor_benutzen} = $self->build_widgets($toplevel);
        
        return $self;
} # /new

sub build_widgets {
        my $self = shift;
        my $toplevel = shift or die('Missing toplevel widget');
        
        my $frame = $toplevel->Frame()->pack;
        my $name = $frame->Entry( )->pack;
        my $alter = $frame->Entry( )->pack;
        my $button = $frame->Button(
                -text => "Ausgabe",
                #-command => \&ausgabe,
        )->pack;

        my %map = (
                toplevel => $toplevel,
                frame => $frame,
                name => $name,
                alter => $alter,
                button => $button,
        );

        $button->configure(-command => sub{ $self->ausgabe(); return 1; });
        
        return \%map;
} # /build_widgets

sub ausgabe {
        my $self = shift;
        my $itemhref = $self->{todo_class_accessor_benutzen};
        print $itemhref->{name}->get()." ". $itemhref->{alter}->get()."\n";
        
        return;
} # /ausgabe

1;

use strict;
use warnings;
use Tk;

my $mw = MainWindow->new();

my $w = MyWidget->new($mw);

$mw->MainLoop();

exit(0);

http://www.intergastro-service.de (mein erstes CMS :) )

View all threads created 2012-02-23 14:12.