Dateien und Ordner packen (Allgemeines zu Perl)

[thread]17626[/thread]

Dateien und Ordner packen

Tags: perl5 Similar Threads

Readers: 22

Articles: hide open all | hide show old branches

+5 replies

karl34

2012-08-02 21:55

User since
2011-10-24
5 articles
BenutzerIn
[default_avatar]

Hallo zusammen,

ich versuche mir ein Perl Script zu bauen, dass mir alle Dateien und Ordner plus Dateien und Unterordner da drunter packt.
Leider kann ich nur in der erste Eben packen, alles was sich da drunter befindet wird nicht gepackt :-(
Die gepackte Ordner sind auch leer :-(

Hier mein Entwurf:

Code: (dl )

#! /usr/bin/perl 

use strict;
use warnings;

use Cwd;
use Archive::Tar;
use IO::Zlib;
use IO::Compress::Bzip2 qw(bzip2 $Bzip2Error) ;
use Compress::Zlib;
use File::Basename;  

my $strVereichnisZiel = "/home/mein_user/sicherung/";
my $VerzPfadNow = cwd . '/';

my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
my $datum = sprintf "%04d_%02d_%02d" , $year+=1900 , $mon+=1 , $mday ;
my $strZielVerzeichnis = $strVereichnisZiel."sicherung_".$datum.".tar.bz2";

my $result=opendir(DIR,$VerzPfadNow) || die $!;

my @files =  grep { !/(\.|\.sh|\.sh~)$/ } readdir(DIR);
close DIR;

my $tar = Archive::Tar->new;

foreach my $dateien ( @files ) 
{
      print "$dateien\n"; # nur Testausgabe
      $tar->add_files( $dateien);
}
$tar->write( $VerzPfadNow."datei_jetzt6_1.tar" );

# ab hier versuche es zu packe,
# funktioniert leider nicht

#Archive::Tar->create_archive(  $VerzPfadNow."datei_jetzt4_2.tbz", COMPRESS_BZIP,  $VerzPfadNow."datei_jetzt2.tar" );    
#Archive::Tar->create_archive(  $VerzPfadNow."datei_jetzt7.tbz", COMPRESS_BZIP,  @listeDatei );

Kann mir jemand ein Tipp geben, wie kann ich die Daten packen?
Danke im Vorraus.

Grüße
karl

Patterner

2012-08-02 22:50

User since
2007-01-02
25 articles
BenutzerIn

add_files() sieht nicht so aus als ob es mit Verzeichnissen umgehen könnte.
Vermutlich musst Du die Unterverzeichnisse selber auslesen und deren Dateien hinzufügen.
“I’m working on it.”
+3 replies

topeg

2012-08-02 23:17

User since
2006-07-10
2611 articles
BenutzerIn

user image

Willst du so was machen?

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;

use Cwd;
use Archive::Tar;
use File::Find;
use File::Spec;
use POSIX qw(strftime);

my $strVereichnisZiel = "/home/mein_user/sicherung/";
my $VerzPfadNow = cwd();

my $datum = strftime("%Y_%m_%d" , localtime() );
my $archiveFile = File::Spec->join( $strVereichnisZiel, sprintf( 'sicherung_%s.tar.bz2', $datum ) );

my $tar = Archive::Tar->new;

find({
  wanted => sub{
    return if( /(\.|\.sh|\.sh~)$/ );
    my $path = $File::Find::name;
    return if( -d $path );
    my ( $file ) = $tar->add_files( $path );
    my $name = File::Spec->abs2rel( $path, $VerzPfadNow );
    $file->rename( $name );
  },
  no_chdir => 1,
}, $VerzPfadNow );

$tar->write( $archiveFile, COMPRESS_BZIP );

Edit: Tippfehler: sprintf nicht printf
Last edited: 2012-08-05 20:13:34 +0200 (CEST)

+2 replies

karl34

2012-08-05 18:24

User since
2011-10-24
5 articles
BenutzerIn
[default_avatar]

Hallo zusammen,

@topeg
Danke für Deine Hilfe, das ist was ich gesucht habe, trotz dem das fast alle was im "find" geschieht ist für mich zu hoch.

Noch was habe eine kleine Änderung eingebaut, bzgl. des Dateinamen.

Code: (dl )

1
2

my $fileEnding ='sicherung_'.$datum.'.tar.bz2';
my $archiveFile = File::Spec->join( $strVereichnisZiel, $fileEnding );

Org. von Dir:

Code: (dl )

# my $archiveFile = File::Spec->join( $strVereichnisZiel, printf( 'sicherung_%s.tar.bz2', $datum ) );

Der Grund, das Archiv wurde zwar erstellt aber immer nur mit dem Namen "1".

Grüße
karl

topeg

2012-08-05 20:19

User since
2006-07-10
2611 articles
BenutzerIn

user image

2012-08-05T16:24:01 karl34
Danke für Deine Hilfe, das ist was ich gesucht habe, trotz dem das fast alle was im "find" geschieht ist für mich zu hoch.

Code (perl): (dl )

    # in $_ steht der aktuelle Dateiname
    # springe aus der anonymen Funktion wenn . oder sh oder .sh~
    return if( /(\.|\.sh|\.sh~)$/ );

    # der aktuelle Pfad
    my $path = $File::Find::name;

    # springe aus der anonymen Funktion, wenn es ein Ordner ist
    return if( -d $path );

    # füge dem Archiv die Datei hinzu
    my ( $file ) = $tar->add_files( $path );

    # mache aus dem Absoluten Pfad einen relativen bezüglich $VerzPfadNow
    my $name = File::Spec->abs2rel( $path, $VerzPfadNow );

    # ändere den Namen im Archiv
    $file->rename( $name );

2012-08-05T16:24:01 karl34
Der Grund, das Archiv wurde zwar erstellt aber immer nur mit dem Namen "1".

Ich habe das "s" bei sprintf vergessen. ist ergänzt

EDIT: Satz vernünftig geschrieben. War ja nicht zu verstehen.
Last edited: 2012-08-06 13:22:48 +0200 (CEST)

View all threads created 2012-08-02 21:55.