mehrere SysLogFiles in ein SysLogFile kopieren (gelöst) (Allgemeines zu Perl)

[thread]18206[/thread]

mehrere SysLogFiles in ein SysLogFile kopieren [gelöst]

Tags: perl5 SysLog Ähnliche Threads

Leser: 13

Articles: hide open all | hide show old branches

+3 replies

cohama

2013-03-14 07:38

User since
2011-08-16
102 Artikel
BenutzerIn

user image

Guten Morgen,

im Moment schlage ich mich mit der Aufgabe rum, dass ich mehrere SysLog-Dateien aus einem Ringspeicher in eine SysLog-Datei zusammenkopieren will.
Hier im Forum finde ich stets Beispiele für binary-Files.

Hier ist mein Ansatz:

Code: (dl )

#!/usr/bin/perl -w
########################################
# Modules
use strict;				# parameter Definition before use them
use File::Copy;
use DateTime;				# Libary for Date operation
#######################################
# Parameter Definition
my ($ct,$idx,$idx2,$idx3,$numbers,$inPut,$outPut);				# counter parameter
my $tstamp = DateTime->now->set_time_zone('Europe/Berlin');	# Find the Timestamp
my $mydate = $tstamp->ymd;

my $folder 	= "./workingFolder";
my $OutFolder	= "./workingFolder/ReadyLogs/";
my $preFix	= "server.log";
my (@filelist,@lines);
###########################
# Main 
system("clear");

@filelist = glob($folder.'/server.log.*');
#print join("\n", @filelist,"\n"); 
rename($folder."/server.log",$folder."/01.log");
$idx	= 11;
$idx2	= $idx-1;
for($ct=1;$ct<=10;$ct++){
#	print `pwd`;					# Output working directory	
	$idx	=sprintf("%02d",$idx);			# Put Zero in Front
	$inPut 	=$folder."/".$preFix.".".$idx2;
	$outPut	=$folder."/".$idx.".log";
#	print "Input: $inPut, Output: $outPut \n";
	rename($inPut,$outPut) || die "Error during Rename: $!";
	$idx--;
	$idx2--;
}
for($ct=11;$ct>0;$ct--){
	
	open(INFile,"<",$folder."/".$ct.".log");
	open(OFile,">>",$OutFolder."/".$mydate."-ServerMessages.log");
	@lines=<INFile>;
	print OFile @lines;
	close(INFile);
}

Hat jemand wieder einen dieser tollen Tipps für mich?
Die erste For-Schleife sorgt dafür, dass die einzelen SysLog-Dateien in richtiger Reihenfolge durch nummeriert werden.
Danach in For-Schleife zwei versuche ich die jeweiligen Dateien stets in eine Ausgangsdatei zu kopieren.

+2 replies

topeg

2013-03-14 12:03

User since
2006-07-10
2611 Artikel
BenutzerIn

user image

Wo genau ist dein Problem?

Hier mal wie ich es machen würde:

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;
use DateTime;

my $folder  = "./workingFolder/";
my $OutFolder = "./workingFolder/ReadyLogs/";
my $preFix  = "server.log";

# LogDateiNamen holen und Liste sortieren
my @logs=
  map {$_->[1]}
    sort {$a->[0] <=> $b->[0]}
      map {[/(\d+)$/?$1:0,$_]}
        glob($folder.$preFix.'*');

# Logs umbenennen
# neue Namen merken
my @to_join;
my $count=0;
for my $old (@logs)
{
  my $new = sprintf($folder."%02d.log",$count++);
  rename($old,$new) or die qq(Error during Rename "$old" => "$new": $!);
  push(@to_join,$new);
}

# BackupLog erzeugen
my $mydate = DateTime->now->set_time_zone('Europe/Berlin')->ymd;  # Find the Timestamp
my $outfile=$OutFolder.$mydate."-ServerMessages.log";
open(my $ofh, '>', $outfile) or die qq(Error during Open "$outfile": $!);
for my $file (@to_join)
{
  open(my $ifh, '<', $file) or die qq(Error during Open "$file": $!);
  # langsam aber Speicher schonend
  # kopiere Zeile für Zeile
  print $ofh $_ while( <$ifh> );
  close($ifh);
}
close($ofh);

# lösche die umbenannten Logs
# ansonsten gibt es Probleme beim nächsten Backup
unlink(@to_join);

cohama

2013-03-14 13:29

User since
2011-08-16
102 Artikel
BenutzerIn

Hallo Topeg,

vielen Dank für deinen Ansatz, es funktioniert ganz wunderbar.Ich habe nur kurz die Sortvorschrift umgedreht, da sonst meine Logs chronologisch anders herum ablaufen.
Nochmal vielen Dank

View all threads created 2013-03-14 07:38.