Hash Struktur rekursiv durchsuchen (solved) (Allgemeines zu Perl)

[thread]18676[/thread]

Hash Struktur rekursiv durchsuchen [solved]

Tags: perl5 hash rekursiv durchsuchen Similar Threads

Readers: 13

Articles: hide open all | hide show old branches

+3 replies

bianca

2013-10-15 18:38

User since
2009-09-13
7016 articles
BenutzerIn

user image

Hi!
Ich möchte gern, dass mein Code eine unbekannte Hash Struktur rekursiv nach einem Begriff durchsucht.
Habe mir das ungefähr so vorgestellt:

Code (perl): (dl )

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;

my %hash = (
    strang1 => {
        string  => 'string foo1',
        hash    => {
            'key foo2' => 'value foo3',
        },
        array   => [
            'foo4 im Array0',
            'foo5 im Array1',
        ],
    },
);

print rekursive_hash_suche(\%hash,'foo');

sub rekursive_hash_suche {
    my ($ref,$suche) = @_;
    my %algo;
    $algo{SCALAR} = sub {
        my ($ref,$suche) = @_;
        my $fund = 0;
        $fund = 1 if $ref =~ /foo/;
        $fund;
    };
    $algo{ARRAY} = sub {
        my ($ref,$suche) = @_;
        my $fund = 0;
        foreach my $k (@$ref) {
            my $fund = $algo{ref($ref->{$k})}($ref,$suche);
            last if $fund;
        }
        $fund;
    };
    $algo{HASH} = sub {
        my ($ref,$suche) = @_;
        my $fund = 0;
        foreach my $k (keys %$ref) {
print "ref:".ref($ref->{$k})." in ".$ref->{$k}."\n";
            my $fund = $algo{ref($ref->{$k})}($ref,$suche);
            last if $fund;
        }
        $fund;
    };
    return $algo{HASH}($ref,$suche);
}

Haufenweise Fehlermeldungen.
Bitte um Hilfe.
Was ich auch nicht genau weiß ist, wie ich das Ergebnis zurück gebe. Haben möchte ich als Ergebnis gern "strang1". Wenn es mehrere sind gern als Array mit den ganzen Keys.

10 print "Hallo"
20 goto 10

+2 replies

2013-10-15 19:04

User since
2003-08-04
12208 articles
Admin1

Code (perl): (dl )

my @result = search(\%hash, 'foo');

sub search {
    my ($hash, $search) = @_;
    my @result;
    for my $key (keys %$hash) {
        my $found = search_data($hash->{ $key }, $search);
        push @result, $key if $found;
    }
    return @result;
}

sub search_data {
    my ($ref, $search) = @_;
    if (ref($ref) eq 'HASH') {
        for my $key (keys %$ref) {
            return 1 if $key =~ m/$search/;
            return 1 if search_data($ref->{ $key }, $search);
        }
    }
    elsif (ref($ref) eq 'ARRAY') {
        for my $item (@$ref) {
            return 1 if search_data($item, $search);
        }
    }
    elsif (ref($ref) eq 'SCALAR') {
        return search_data($$ref, $search);
    }
    elsif (ref($ref) eq 'REF') {
        return search_data($$ref, $search);
    }
    elsif (ref($ref) eq '') {
        return 1 if $ref =~ m/$search/;
    }
    return 0;
}

Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live. -- Damian Conway in "Perl Best Practices"
lesen: Wiki:

Wie frage ich & perlintro Wiki:

brian's Leitfaden für jedes Perl-Problem

bianca

2013-10-16 08:03

User since
2009-09-13
7016 articles
BenutzerIn

Klasse! Danke dir!
10 print "Hallo"
20 goto 10

View all threads created 2013-10-15 18:38.