Perl/tk, bind bei Textwidgets, html in widgets (Seite 2) (Graphische Oberflächen)

[thread]4701[/thread]

Perl/tk, bind bei Textwidgets, html in widgets (Seite 2)

Crian

2004-01-16 21:30

User since
2003-08-04
5873 Artikel
ModeratorIn

[quote=Frühstücker,16.01.2004, 16:58]Nein, wohl leider nicht, so wie es klingt hätte ich es tun sollen. ;)
[/quote]

Naja, Herr Lehmann hasst "Frühstücker" als Spätaufsteher ;)

[quote=Frühstücker,16.01.2004, 16:58]Vielen, vielen Dank für deinen Code, er ist wahrhaftig einer der besten Tk Codes ever seen und ich schreibe eigentlich schon recht lange Perl, d.h. die Syntax ist gut![/quote]

Danke, das ist ja ein tolles Lob :)

[quote=Frühstücker,16.01.2004, 16:58]Du hast mich zwar in der verwendung missverstanden, doch haben unsere beiden Gehirne eigentlich dann doch etwas sehr produktives geschaffen.
Danke, ich glaube ich werde das weiter entwickeln und an einige Leute verteilen, die auflegen :).[/quote]

Ups ... na Glück im Unglück? :D
Wie "auflegen"?

[quote=Frühstücker,16.01.2004, 16:58]Ich wollte viel mehr dieses Programm auf eine CD legen und die auf ihr enthaltenen Dateien durch den Text darunter dokumentieren. :)
[/quote]

Aha, d.h. Du hast zu jeder Datei noch eine kleine Erklärungsdatei, oder eine große Datei, in der alle erklärt werden?
Auf jeden Fall ist das ja kein Problem, den entsprechenden Text statt meiner "CD-Informationen" anzuzeigen. Man muss die Informationen nur irgendwie in ein AoH kriegen in der Art des @CD-AoH's, mit Dateinamen und Erklärungstext.

[quote=Frühstücker,16.01.2004, 16:58]Ich hoffe, es macht dir nichts aus, mir nochmal zu helfen,
auch, wenn du den kleinsten Teil noch ändern musst.
Aber du hast ner gute Idee den Anstoß gegeben :D.[/quote]

Kein Problem.

[quote=Frühstücker,16.01.2004, 16:58]Um nochmal zu verdeutlichen:
Es lieben pdf und word dateien auf der CD, die dann angezeigt werden und von dortaus auch aufgerufen werden sollen; wenn möglich mit dem Standardprogramm für dieses Format :).[/quote]

Sollte man sie nicht in Ruhe lassen? Liebende störe ich ungern ;)

Ok, beim "Ausführen" soll einfach per Systemaufruf die entsprechende Datei "gestartet" werden...

[quote=Frühstücker,16.01.2004, 16:58]Sieht verdächtig unportabel aus ... mache ich aber dann danach :).
Zielsystem ist WinXP, da offiziell das System meiner Benutzer so ist, wenn möglich aber so unabhängig wie möglich, da ich Windows GAR nicht mag. :([/quote]

Das Problem der Portabilität kann man bestimmt lösen. Man kann ja abfragen, welches System vorliegt, bei Windowsartigen müsste es dann reichen, einfach die Datei "auszuführen", dann startet hoffentlich die Standardanwendung, für Linux könnte man ev. Betrachter aufrufen, die Standard sind oder welche mit auf die CD packen und diese benutzen?

Der Not folgend arbeite ich zur Zeit fast ausschließlich unter Windows... dafür ist die Arbeit (meist) so interessant, dass ich wirklich nicht weg möchte, obwohl ich eigentlich auch *nix-Systeme bevorzugen würde. Obwohl ich mich inzwischen wohl erstmal wieder umstellen müsste...

[quote=Frühstücker,16.01.2004, 16:58]P.S.: Ich nehme den Code gerne formatiert :)[/quote]

Ok, wenn wir fertig sind, schick ich ihn Dir. Im Prinzip fehlt bei allen eingerückten Zeilen das erste Whitespace.

[quote=Frühstücker,16.01.2004, 16:58]P.P.S.: Hast du "Der Blingfisch" von Knippfel gelesen?[/quote]

Nein. Sollte ich? Klingt so :D

s--Pevna-;s.([a-z]).chr((ord($1)-84)%26+97).gee; s^([A-Z])^chr((ord($1)-52)%26+65)^gee;print;

use strict; use warnings; Link zu meiner Perlseite

Crian

2004-01-16 22:38

User since
2003-08-04
5873 Artikel
ModeratorIn

So ... ich habe es etwas umgearbeitet, aber ich bekomme die Dateien einfach nicht ausgeführt, weder als Dateien direkt, noch mit dem Programm vorweg ...

Code: (dl )

#!/usr/bin/perl

#------------------------------------------------------------------------------
# Pragmas und Module:
#------------------------------------------------------------------------------
use strict;
use warnings;

use Tk;

#------------------------------------------------------------------------------
# Globales Kofigurationshash:
#------------------------------------------------------------------------------
my %Config = ( debug         => 1,                    # Debuginformationen?
               version       => '0.0.2',              # Programmversion
               version_datum => '16.01.2004',         # Programmdatum

               main_window   => undef,                # Hauptfenster-Widget
               ausg_widget   => undef,                # Ausgabe-Widget
               Menu          => undef,                # Menu-Widget
               Menuefont     => '{Arial} 8 {normal}', # Schriftart des Menu

               Titel         => 'Frühstückers CD Oberfläche',
                                                      # Fenstertitel
             );

#------------------------------------------------------------------------------
# CDdaten (ein AoH):
#------------------------------------------------------------------------------
my @Files = (
          {
           name => 'Testdatei1.doc',
           info => "1\nBla bla laber fasel sabbel anpreis \nschwafel\nrhabrhab",
          },
          {
           name => 'Testdatei2.doc',
           info => "2\nBla bla laber fasel sabbel anpreis \nschwafel\nrhabrhab",
          },
          {
           name => 'Testdatei3.pdf',
           info => "3\nBla bla laber fasel sabbel anpreis \nschwafel\nrhabrhab",
          },
          {
           name => 'Testdatei4.doc',
           info => "4\nBla bla laber fasel sabbel anpreis \nschwafel\nrhabrhab",
          },
          {
           name => 'Testdatei5.pdf',
           info => "5\nBla bla laber fasel sabbel anpreis \nschwafel\nrhabrhab",
          },
         );

#------------------------------------------------------------------------------
# Prototypen:
#------------------------------------------------------------------------------
sub tk_main ();
sub show_data ($);
sub show_data ($);
sub clear_data ();
sub anzeigen ($);

#------------------------------------------------------------------------------
# Programmablauf:
#------------------------------------------------------------------------------
tk_main();

MainLoop();
exit;


sub tk_main () {
    print "tk_main()\n" if $Config{debug};

    #--------------------------------------------------------------------------
    # Hauptfenster erzeugen und Fenstertitel vergeben:
    #--------------------------------------------------------------------------
    my $mw = new MainWindow;
    $Config{main_window} = $mw;

    $mw->title($Config{Titel});

    #--------------------------------------------------------------------------
    # Menü erzeugen:
    #--------------------------------------------------------------------------

    # 1. Menu-Bar erstellen:
    $Config{Menu} = $mw->Menu(-type => 'menubar',
                              -font => $Config{Menuefont},
                             );

    # 2. Dem Fensterwidget sagen, dass unsere Menubar sein Menu ist:
    $mw->configure(-menu => $Config{Menu});

    # 3. Einträge in der Menu-Bar:
    $Config{Menu}->cascade(-label     => 'Datei',
                           -underline => 0,
                           -font      => $Config{Menuefont},
                          );
    $Config{Menu}->separator(); # dadurch wird der Rest rechtsbündig
    $Config{Menu}->cascade(-label     => 'Hilfe',
                           -underline => 0,
                           -font      => $Config{Menuefont},
                          );

    # 4. Die einzelnen Untermenüs definieren:
    # Zunächst das Dateimenü:
    my $menu_datei = $Config{Menu}
         ->Menu(-font      => $Config{Menuefont}, # Schriftart des Menüs
                -tearoff   => 0,                  # Menü nicht abreißbar
                -menuitems => [
                                [
                                 'command'    => 'Speichern',
                                 #-command     => \&save,
                                 -command     => sub { print "\a" },
                                 -accelerator => 'F2',
                                 -font        => $Config{Menuefont},
                                 -underline   => 0,
                                ],
                                [
                                 'command'    => 'Speichern unter',
                                 #-command     => \&saveas,
                                 -command     => sub { print "\a" },
                                 -accelerator => 'F12',
                                 -font        => $Config{Menuefont},
                                 -underline   => 10,
                                ],
                                '-',
                                [
                                 'command'    => 'Beenden',
                                 -command     => sub { $mw->destroy() },
                                 -font        => $Config{Menuefont},
                                 -underline   => 0,
                                 -accelerator => 'Esc',
                                ],
                              ],
               );
    # Dazu gehört auch, der Menubar zu sagen, dass dieses Untermenü zu seinem
    # Eintrag "Datei" gehört:
    $Config{Menu}->entryconfigure('Datei', -menu => $menu_datei);

    # Analog für die anderen Menüs:

    # Hilfemenü:
    my $menu_hilfe = $Config{Menu}
         ->Menu(-font      => $Config{Menuefont},
                -tearoff   => 0,
                -menuitems => [
                                [
                                 'command'    => "Hilfe",
                                 #-command     => \&hilfe,
                                 -command     => sub { print "\a" },
                                 -accelerator => 'F1',
                                 -font        => $Config{Menuefont},
                                 -underline   => 0,
                                ],
                                '-',
                                [
                                 'command'    => "Über ...",
                                 #-command     => \&ueber,
                                 -command     => sub { print "\a" },
                                 -font        => $Config{Menuefont},
                                 -underline   => 0,
                                ],
                              ],
               );
    $Config{Menu}->entryconfigure('Hilfe', -menu => $menu_hilfe);


    #--------------------------------------------------------------------------
    # Hauptfeld:
    #--------------------------------------------------------------------------
    my $txt = $mw->Scrolled("Text",
                            -scrollbars => 'osoe',
                            #-background => $bcolor,
                            #-foreground => $tcolor,
                            -width      => 80,
                            -height     => 15,
                            -relief     => 'flat',
                            -wrap       => 'none',
                           )
                     ->pack(-side       => 'top',
                            -expand     => 1,
                            -fill       => 'both',
                           );

    for my $index (0..$#Files) {
        my $btn = $mw->Button(-text   => $Files[$index]->{name},
                              -width  => 80,
                              -relief => 'flat',
                              -anchor => 'w',
                              -command => [ \&anzeigen, $index ],
                              );

        $btn->bind('<Enter>' => sub { show_data($index)  } );
        $btn->bind('<Leave>' => sub { clear_data } );

        $txt->windowCreate('end', -window => $btn);
        $txt->insert('end', "\n");
    }

    $txt->configure(-state => 'disabled');

    #--------------------------------------------------------------------------
    # Ausgabefeld:
    #--------------------------------------------------------------------------
    my $aus = $mw->Scrolled("Text",
                            -scrollbars => 'osoe',
                            -width      => 80,
                            -height     => 4,
                            -relief     => 'flat',
                            -wrap       => 'none',
                            -background => '#FFFFEE',
                            -foreground => '#FF6600',
                            -state      => 'disabled',
                            -relief     => 'groove',
                           )
                     ->pack(-side       => 'top',
                            -expand     => 1,
                            -fill       => 'both',
                           );
    $Config{ausg_widget} = $aus;

    #--------------------------------------------------------------------------
    # Bindungen:
    #--------------------------------------------------------------------------
    $mw->bind('<Escape>', sub { $mw->destroy() } ); # Ctrl-B: Beenden
    #$mw->bind('<F1>',     \&help                 ); # F1: Hilfe
    #$mw->bind('<F2>',     \&save                 ); # F2: Speichern
    #$mw->bind('<F12>',    \&saveas               ); # F12: Speichern unter

} # sub tk_main;


sub show_data ($) {
    print "show_data()\n" if $Config{debug};
    my $index = shift;

    die "Fehlender Parameter in 'show_data'" unless defined $index;
    die "Falscher Parameter '$index' in 'show_data'" unless $index >= 0 and
                                                            $index <= $#Files;

    my $text = "Datei: " . $Files[$index]->{name} . "\n" .
               "Info : " . $Files[$index]->{info} . "\n";

    $Config{ausg_widget}->configure(-state => 'normal');
    $Config{ausg_widget}->delete('1.0', 'end');
    $Config{ausg_widget}->insert('end', $text);
    #$Config{ausg_widget}->insert('end', "\n");
    $Config{ausg_widget}->configure(-state => 'disabled');

} # sub show_data


sub clear_data () {
    print "clear_data()\n" if $Config{debug};
    $Config{ausg_widget}->configure(-state => 'normal');
    $Config{ausg_widget}->delete('1.0', 'end');
    $Config{ausg_widget}->configure(-state => 'disabled');
} # sub clear_data


sub anzeigen ($) {
    print "anzeigen()\n" if $Config{debug};
    my $index = shift;

    die "Fehlender Parameter in 'anzeigen'" unless defined $index;
    die "Falscher Parameter '$index' in 'anzeigen'" unless $index >= 0 and
                                                           $index <= $#Files;

    # ... irgendwas externes mit der Datei anstellen
    print "ANZEIGEN: ", $Files[$index]->{name}, "\n";
    my $prg = $Files[$index]->{name} =~ m~.doc$~ ?
              'c:\programme\microsoft\ office\office\winword.exe' :
              'c:\programme\adobe\acrobat\ 6.0\reader\acrord32.exe';
    print "Führe aus: '$prg $Files[$index]->{name}'\n";
    my $ret = qx($prg $Files[$index]->{name});

} # sub anzeigen

Da musst Du ev. noch ein bischen rumprobieren in der letzten Funktion...

Ist es jetzt mehr so wie Du dachtest?

s--Pevna-;s.([a-z]).chr((ord($1)-84)%26+97).gee; s^([A-Z])^chr((ord($1)-52)%26+65)^gee;print;

use strict; use warnings; Link zu meiner Perlseite

Frühstücker

2004-01-17 12:00

User since
2003-10-31
9 Artikel
BenutzerIn
[default_avatar]

Jawohl, jetzt gefällt es mir schon viel besser ;).

Das BUch heißt der BlinDfisch ... war gestern sau übermüdet etc.
Ich meine, man könnte ggf diese Programme mit Hilfe des Moduls Win32::OLE aufrufen, bez direkt mit Win32::OLE::CreateObject :) ... hatte das mal vor längerem gemacht.
Ich werde dann gegen später, wenn alles klappt eine Googlesuche einbauen, die von sich aus dann den IE aufruft un die Argumente übergibt.
Diese ist bereits sogar annähernd fertig :).

View all threads created 2004-01-15 11:21.