Timer: Einrichten einer stopuhr (Graphische Oberflächen)

[thread]4866[/thread]

Timer: Einrichten einer stopuhr

Gast Gast

2005-02-23 15:20

hi kann mir jemand helfen eine art Stopuhr zu erstellen die man mit einem button start und button stop???

danke schon mal im vorraus

ptk

2005-02-23 15:26

User since
2003-11-28
3645 Artikel
ModeratorIn
[default_avatar]

Als Perl/Tk-Version kannst du das Perl-Plugin http://search.cpan.org/src/FHOLTRY/ppl-plug-0.95/samples/thunder.ppl als Vorlage verwenden. Man muss nur die MainWindow-Zeile so aendern:

Code: (dl )

$top = new MainWindow();#-use => $Plugin::brinfo{xwindow_id});

Dubu

2005-02-23 23:39

User since
2003-08-04
2145 Artikel
ModeratorIn + EditorIn

user image

Code: (dl )

#!/usr/bin/perl
use strict;
use warnings;
use Time::HiRes qw/time/;
use Tk;

my ($Startzeit, $Zeit, $Delta, $Ticker)=(0,0,0,undef);
my $Mw = MainWindow->new;
$Mw->Label(-textvariable => \$Zeit)->pack;
my $Fr = $Mw->Frame->pack;
$Fr->Button(-text => 'Start', -command => \&start)->pack(-side => 'left');
$Fr->Button(-text => 'Stop',  -command => \&stop)->pack(-side => 'left');
$Fr->Button(-text => 'Reset', -command => \&reset)->pack(-side => 'left');
show(0);
$Mw->MainLoop;

sub start { return if $Ticker; $Startzeit = time - $Delta; $Ticker = $Mw->repeat(50, \&calc) }
sub stop  { $Mw->afterCancel($Ticker) if $Ticker; $Ticker = undef }
sub reset { $Delta = 0; show(0) }
sub calc  { $Delta = time - $Startzeit; show($Delta) }
sub show  { $Zeit = sprintf "%d:%02d.%02d", int($_[0]/60), $_[0]%60, int(($_[0] - int $_[0])*100) }

Crian

2005-03-14 17:25

User since
2003-08-04
5878 Artikel
ModeratorIn

Nett, gleich abgespeichert, das kann ich bestimmt irgendwo verwursten ;)

s--Pevna-;s.([a-z]).chr((ord($1)-84)%26+97).gee; s^([A-Z])^chr((ord($1)-52)%26+65)^gee;print;

use strict; use warnings; Link zu meiner Perlseite

View all threads created 2005-02-23 15:20.