Project Euler (Projekte) - Perl-Community.de

[thread]11032[/thread]

Project Euler

Leser: 34

Ronnie

2007-12-15 12:19

User since
2003-08-14
2022 Artikel
BenutzerIn
[default_avatar]

Hallo zusammen,

das Project Euler (http://projecteuler.net/index.php?section=problems) bietet ein reiches Angebot an Programmieraufgaben. Wäre doch eine nette Spielerei in der RDW-freien Zeit, oder?

Für die ersten zwei Aufgaben hätte ich schon eine Lösung anzubieten. Hat jemand Interesse mitzuknobbeln?

Gruß,
Ronnie

Gast Gast

2007-12-30 13:50

Interessante Aufgaben, tolle Seite!
Danke für den Link!

MfG Horst

Ronnie

2007-12-30 14:26

User since
2003-08-14
2022 Artikel
BenutzerIn
[default_avatar]

Ich hatte zuletzt besonders viel Spass an Aufgabe 11. Habe eine Lösung mit Tk::Table anzubieten, wenn Interesse besteht?!

Gruß,
Ronnie

styx-cc

2007-12-30 15:10

User since
2006-05-20
533 Artikel
BenutzerIn

user image

Oh, bis jetzt uebersehen..
Gibst du uns noch ein bisschen Zeit, bis du deine Loesung Postest? :-)

Pörl.

Ronnie

2007-12-30 15:13

User since
2003-08-14
2022 Artikel
BenutzerIn
[default_avatar]

styx-cc+2007-12-30 14:10:55--
Gibst du uns noch ein bisschen Zeit, bis du deine Loesung Postest? :-)

Klar, gerne :)

styx-cc

2007-12-30 20:13

User since
2006-05-20
533 Artikel
BenutzerIn

user image

So, Aufgabe 1,2,10 und 11 sind geloest.
Hat mir den Sonntag versüßt =)

P.s. Freundin meckert *g*

Pörl.

Ronnie

2007-12-30 21:00

User since
2003-08-14
2022 Artikel
BenutzerIn
[default_avatar]

Gut, dann mal hier die Lösung zur Aufgabe 11:

Code (perl): (dl )

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;
use Tk;
use Tk::Table;
use Tk::BrowseEntry;

package EulerTable;
use List::Util qw/reduce/;
use Data::Dumper;

sub new {
    my $class = shift;
    my $self  = [];
    return bless $self, $class;
}

sub append_row {
    my $self = shift;
    my $row  = shift;
    return unless ref $row;
    push @$self, $row if @$self == 0 or @$row == @{$self->[0]};
}

sub max_idx_y { my $self = shift; return $#$self; }
sub max_idx_x { my $self = shift; return $#{$self->[0]}; }

sub collect {
    my $self    = shift;
    my ($dir, $x, $y, $n, $cb) = @_; #$ callback ununsed 'til now
    $n = $n ? $n -1 : 3;
    
    my $sanitize = {
        'right'   => sub { $x > $self->max_idx_x - $n },
        'down'    => sub { $y > $self->max_idx_y - $n },
        'diag_dr' => sub { 
            $y > $self->max_idx_y - $n 
            or $x > $self->max_idx_x - $n
        },
        'diag_dl' => sub { 
            $x > $self->max_idx_x 
            or $y > $self->max_idx_y - $n 
            or $x < $n
        },
    };
    
    return if $sanitize->{$dir}->();
    
    return [map {$self->[$y]->[$x+$_]} 0..$n ] if $dir eq 'right';
    return [map {$self->[$y+$_]->[$x]} 0..$n ] if $dir eq 'down';
    return [map {$self->[$y+$_]->[$x+$_]} 0..$n ] if $dir eq 'diag_dr';
    return [map {$self->[$y+$_]->[$x-$_]} 0..$n ] if $dir eq 'diag_dl';
}

sub mark_by { 
    my $self    = shift;
    my ($what, $x, $y, $n, $cb) = @_;
    $n = $n ? $n -1 : 3;
    
    if ($what eq 'right')   { $cb->($x+$_,$y)    for 0..$n }
    if ($what eq 'down')    { $cb->($x,$y+$_)    for 0..$n }
    if ($what eq 'diag_dr') { $cb->($x+$_,$y+$_) for 0..$n }
    if ($what eq 'diag_dl') { $cb->($x-$_,$y+$_) for 0..$n }
}

sub process_n_as {
    my $self    = shift;
    my $n       = shift;
    my $func    = shift;
    my $results = {};
    for my $x (0..$self->max_idx_x) {
        for my $y (0..$self->max_idx_y) {
            
            my $r  = $self->collect( right   => $x, $y, $n );
            my $d  = $self->collect( down    => $x, $y, $n );
            my $dr = $self->collect( diag_dr => $x, $y, $n );
            my $dl = $self->collect( diag_dl => $x, $y, $n );
        
            if (defined $r)  { $results->{ "right:$x:$y"   } = $func->(@$r)  }
            if (defined $d)  { $results->{ "down:$x:$y"    } = $func->(@$d)  }
            if (defined $dr) { $results->{ "diag_dr:$x:$y" } = $func->(@$dr) }
            if (defined $dl) { $results->{ "diag_dl:$x:$y" } = $func->(@$dl) }
        }
    }
    return $results;
}

sub find_max_n_by {
    my $self = shift;
    my $n    = shift || 4;
    my $func = shift || sub { no warnings; reduce { $a * $b } @_ }; #defaults to product
    my $res  = $self->process_n_as($n, $func);
    my ($k, $v);
    my $max = [0, 'NULL'];
    
    while (($k, $v) = each %$res) {
        $max = [ $v, $k ] if $v > $max->[0];
    }
    return $max;
}

sub fill_tk_table {
    my $self = shift;
    my $wdgt = shift or die "iter_each() needs a TK::Table wdgt to callback";
    
    $wdgt->clear;
    for my $x (0..$self->max_idx_x) {
        for my $y (0..$self->max_idx_y) {
            $wdgt->put($y,$x,$wdgt->Entry(-text => "$self->[$y]->[$x]", -width => 2, -bg => $y % 2 == 0 ? 'grey' : 'darkgrey'));
        }
    }
}

package main;

my $table = EulerTable->new();
$table->append_row([ split /\s/, $_ ]) while (<DATA>);
my $n = 4; # we want four in a row

my $functions = {
    biggest_sum     => sub { my $s; $s += $_ for @_; $s },
    biggest_product => sub { my $p = 1; $p *= $_ for @_; $p },
    equal_100 => sub { my $s; $s += $_ for @_; $s == 100 ? 1 : 0 },
};

my $mw = MainWindow->new();
my $tk_table = $mw->Table(-scrollbars => 'osoe', -rows => $table->max_idx_y+1, -columns => $table->max_idx_x+1 )->pack(-expand => '1', -fill => 'both');
$table->fill_tk_table($tk_table);

my $cb = sub { # callback for highlighting TK::Table entries
    my ($x, $y) = @_;
    my $widget = $tk_table->get($y,$x);
    $widget->configure(-fg => 'white', -bg => 'darkred');
};

my $lbox_selection;
my $lbox = $mw->BrowseEntry(-label => "Function:", -state => 'readonly', -variable => \$lbox_selection )->pack(-side => 'left');
$lbox->insert('end', keys %$functions );

my $entry = $mw->Entry( -width => '2', -text => \$n )->pack(-side => 'left');

my $btn_1 = $mw->Button( -text=> 'Filter', -command => sub { 
    my $func = $functions->{$lbox_selection} || undef;
    my $results = $table->find_max_n_by($n, $func);
    warn Dumper $results;
    my ($dir, $x, $y) = split /:/, $results->[1];
    $table->mark_by($dir, $x, $y, $n, $cb); # highlight numbers
} )->pack(-side => 'left');

my $btn_2 = $mw->Button( -text=> 'Clear', -command => sub { 
    $table->fill_tk_table($tk_table);
} )->pack(-side => 'left');

MainLoop;

__DATA__
08 02 22 97 38 15 00 40 00 75 04 05 07 78 52 12 50 77 91 08
49 49 99 40 17 81 18 57 60 87 17 40 98 43 69 48 04 56 62 00
81 49 31 73 55 79 14 29 93 71 40 67 53 88 30 03 49 13 36 65
52 70 95 23 04 60 11 42 69 24 68 56 01 32 56 71 37 02 36 91
22 31 16 71 51 67 63 89 41 92 36 54 22 40 40 28 66 33 13 80
24 47 32 60 99 03 45 02 44 75 33 53 78 36 84 20 35 17 12 50
32 98 81 28 64 23 67 10 26 38 40 67 59 54 70 66 18 38 64 70
67 26 20 68 02 62 12 20 95 63 94 39 63 08 40 91 66 49 94 21
24 55 58 05 66 73 99 26 97 17 78 78 96 83 14 88 34 89 63 72
21 36 23 09 75 00 76 44 20 45 35 14 00 61 33 97 34 31 33 95
78 17 53 28 22 75 31 67 15 94 03 80 04 62 16 14 09 53 56 92
16 39 05 42 96 35 31 47 55 58 88 24 00 17 54 24 36 29 85 57
86 56 00 48 35 71 89 07 05 44 44 37 44 60 21 58 51 54 17 58
19 80 81 68 05 94 47 69 28 73 92 13 86 52 17 77 04 89 55 40
04 52 08 83 97 35 99 16 07 97 57 32 16 26 26 79 33 27 98 66
88 36 68 87 57 62 20 72 03 46 33 67 46 55 12 32 63 93 53 69
04 42 16 73 38 25 39 11 24 94 72 18 08 46 29 32 40 62 76 36
20 69 36 41 72 30 23 88 34 62 99 69 82 67 59 85 74 04 36 16
20 73 35 29 78 31 90 01 74 31 49 71 48 86 81 16 23 57 05 54
01 70 54 71 83 51 54 69 16 92 33 48 61 43 52 01 89 19 67 48

Die Klasse EulerTable funktioniert natürlich auch ohne Tk (die Methode fill_tk_table() mal außen vor gelassen. Wichtig war mir, dass die Lösung eine beliebige Funktion, auf eine beliebige Anzahl von Elementen der Tabelle anwenden kann. Obiges Skript ist natürlich nicht die erste Variante die ich geschrieben habe, sondern hat sich im Laufe der Zeit entwickelt, wobei ich versucht habe einen immer größeren Abstraktionsgrad reinzubekommen.

EDIT1: So sieht das ganze ohne Tk aus, um die Übersicht etwas zu erhöhen:

Code (perl): (dl )

my $table = EulerTable->new();
$table->append_row([ split /\s/, $_ ]) while (<DATA>);
my $n = 4; # we want four in a row

my $functions = {
    biggest_sum     => sub { my $s; $s += $_ for @_; $s },
    biggest_product => sub { my $p = 1; $p *= $_ for @_; $p },
    equal_100 => sub { my $s; $s += $_ for @_; $s == 100 ? 1 : 0 },
};

my $results = $table->find_max_n_by($n, $functions->{'biggest_product'});
print Dumper $results;

Kommentare und Kritik sind erwünscht!

Gruß,
Ronnie

styx-cc

2007-12-30 21:25

User since
2006-05-20
533 Artikel
BenutzerIn

user image

Meine 11:

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;

my @table;
for (<DATA>) {
  last if ($_ =~ m/^###/);
  chomp;
  push @table, [split / /];
}
my %highest = (a => [0,0], b => [0,0],
               c => [0,0], d => [0,0], 
               sum => 0);

for (my $row=0; $row < $#table; $row++) {
  for (my $col=0; $col <= $#{$table[0]}; $col++ ) {
    get_highest($row, $col);
  }
}

print "The four coherent numbers, which have the highest product:\n";
for my $key (sort keys %highest) {
  next if ($key eq 'sum');
  print "$key => [$highest{$key}->[0],$highest{$key}->[1]] = $table[$highest{$key}->[0]]->[$highest{$key}->[1]]\n";
}

sub get_highest {
  my ($row, $col) = @_;
  my @steps = qw/c- c-r- r- c+r+ c+ c+r- r+ c-r+/;
  for my $step (@steps) {
    my ($tmp_row, $tmp_col) = ($row, $col);
    my $sum = 0;
    my @cur_coords;
    for (0..3) {
      last unless $table[$tmp_row]->[$tmp_col];
      $sum += $table[$tmp_row]->[$tmp_col]; 
      push @cur_coords, [$tmp_row, $tmp_col];
      $tmp_row-- if($step =~ m/r\-/);
      $tmp_col-- if($step =~ m/c\-/);
      $tmp_row++ if($step =~ m/r\+/);
      $tmp_col++ if($step =~ m/c\+/);
    }
    if ( ($sum > $highest{'sum'}) && (scalar @cur_coords > 3) ) {
      $highest{'sum'} = $sum;
      my $i=0;
      for my $key (sort keys %highest) {
        next if ($key eq 'sum');
        $highest{$key} = [$cur_coords[$i]->[0], $cur_coords[$i]->[1]];
        $i++;
      }
    }
  }
}

__DATA__
08 02 22 97 38 15 00 40 00 75 04 05 07 78 52 12 50 77 91 08
49 49 99 40 17 81 18 57 60 87 17 40 98 43 69 48 04 56 62 00
81 49 31 73 55 79 14 29 93 71 40 67 53 88 30 03 49 13 36 65
52 70 95 23 04 60 11 42 69 24 68 56 01 32 56 71 37 02 36 91
22 31 16 71 51 67 63 89 41 92 36 54 22 40 40 28 66 33 13 80
24 47 32 60 99 03 45 02 44 75 33 53 78 36 84 20 35 17 12 50
32 98 81 28 64 23 67 10 26 38 40 67 59 54 70 66 18 38 64 70
67 26 20 68 02 62 12 20 95 63 94 39 63 08 40 91 66 49 94 21
24 55 58 05 66 73 99 26 97 17 78 78 96 83 14 88 34 89 63 72
21 36 23 09 75 00 76 44 20 45 35 14 00 61 33 97 34 31 33 95
78 17 53 28 22 75 31 67 15 94 03 80 04 62 16 14 09 53 56 92
16 39 05 42 96 35 31 47 55 58 88 24 00 17 54 24 36 29 85 57
86 56 00 48 35 71 89 07 05 44 44 37 44 60 21 58 51 54 17 58
19 80 81 68 05 94 47 69 28 73 92 13 86 52 17 77 04 89 55 40
04 52 08 83 97 35 99 16 07 97 57 32 16 26 26 79 33 27 98 66
88 36 68 87 57 62 20 72 03 46 33 67 46 55 12 32 63 93 53 69
04 42 16 73 38 25 39 11 24 94 72 18 08 46 29 32 40 62 76 36
20 69 36 41 72 30 23 88 34 62 99 69 82 67 59 85 74 04 36 16
20 73 35 29 78 31 90 01 74 31 49 71 48 86 81 16 23 57 05 54
01 70 54 71 83 51 54 69 16 92 33 48 61 43 52 01 89 19 67 48
###

Natuerlich hab auch ich Kritik gerne.
Schau mir deins jetzt mal in Ruhe an.

Pörl.

renee

2007-12-30 21:33

User since
2003-08-04
14371 Artikel
ModeratorIn

@styx-cc: Anstatt der ersten for-Schleife würde ich eine while-Schleife nehmen. Du liest hier erst alles in eine Liste ein, obwohl Du diese nicht benötigst...

for (my $row=0; $row < $#table; $row++) { warum '< $#table'? Kann denn nicht im letzten Element der höchste Wert sein? Also entweder '<= $#table' oder '< scalar @table'.

Und dann ist es "perlisher" for my $row ( 0 .. $#table ){ zu schreiben...

Bei Ronnie brauche ich länger, um es durchzugehen ;-)

OTRS-Erweiterungen (http://feature-addons.de/)
Frankfurt Perlmongers (http://frankfurt.pm/)
--

Unterlagen OTRS-Workshop 2012: http://otrs.perl-services.de/workshop.html
Perl-Entwicklung: http://perl-services.de/

styx-cc

2007-12-30 22:08

User since
2006-05-20
533 Artikel
BenutzerIn

user image

So , hab das nochmal getestet und die while-Schleife (hoffentlich richtig) eingebaut, laut den Testausgaben laeuft das Script richtig.

Code (perl): (dl )

#!/usr/bin/perl -w
use strict;

my @table;
for (<DATA>) {
  last if ($_ =~ m/^###/);
  chomp;
  push @table, [split / /];
}
my %highest = (a => [0,0], b => [0,0],
               c => [0,0], d => [0,0], 
               sum => 0);

for (my $row=0; $row < $#table; $row++) {
  for (my $col=0; $col <= $#{$table[0]}; $col++ ) {
    get_highest($row, $col);
  }
}

print "The four coherent numbers, which have the highest product:\n";
for my $key (sort keys %highest) {
  next if ($key eq 'sum');
  print "$key => [$highest{$key}->[0],$highest{$key}->[1]] = $table[$highest{$key}->[0]]->[$highest{$key}->[1]]\n";
}

sub get_highest {
  my ($row, $col) = @_;
  my @steps = qw/c- c-r- r- c+r+ c+ c+r- r+ c-r+/;
  while (my $step = shift @steps) {
    my ($tmp_row, $tmp_col) = ($row, $col);
    my $sum = 0;
    my @cur_coords;
    print "Check [$row, $col]\n";
    for (0..3) {
      last unless $table[$tmp_row]->[$tmp_col];
      print "S $step\t| R $tmp_row | C $tmp_col\n";
      $sum += $table[$tmp_row]->[$tmp_col]; 
      push @cur_coords, [$tmp_row, $tmp_col];
      $tmp_row-- if($step =~ m/r\-/);
      $tmp_col-- if($step =~ m/c\-/);
      $tmp_row++ if($step =~ m/r\+/);
      $tmp_col++ if($step =~ m/c\+/);
    }
    if ( ($sum > $highest{'sum'}) && (scalar @cur_coords > 3) ) {
      $highest{'sum'} = $sum;
      my $i=0;
      for my $key (sort keys %highest) {
        next if ($key eq 'sum');
        $highest{$key} = [$cur_coords[$i]->[0], $cur_coords[$i]->[1]];
        $i++;
      }
    }
  }
}

#data siehe oben
__DATA__

Ausgabe:

Code: (dl )

Check [19, 18]
S c-    | R 19 | C 18
S c-    | R 19 | C 17
S c-    | R 19 | C 16
S c-    | R 19 | C 15
Check [19, 18]
S c-r-  | R 19 | C 18
S c-r-  | R 18 | C 17
S c-r-  | R 17 | C 16
S c-r-  | R 16 | C 15
Check [19, 18]
S r-    | R 19 | C 18
S r-    | R 18 | C 18
S r-    | R 17 | C 18
S r-    | R 16 | C 18
Check [19, 18]
S c+r+  | R 19 | C 18
Check [19, 18]
S c+    | R 19 | C 18
S c+    | R 19 | C 19
Check [19, 18]
S c+r-  | R 19 | C 18
S c+r-  | R 18 | C 19
Check [19, 18]
S r+    | R 19 | C 18
Check [19, 18]
S c-r+  | R 19 | C 18
Check [19, 19]
S c-    | R 19 | C 19
S c-    | R 19 | C 18
S c-    | R 19 | C 17
S c-    | R 19 | C 16
Check [19, 19]
S c-r-  | R 19 | C 19
S c-r-  | R 18 | C 18
S c-r-  | R 17 | C 17
S c-r-  | R 16 | C 16
Check [19, 19]
S r-    | R 19 | C 19
S r-    | R 18 | C 19
S r-    | R 17 | C 19
S r-    | R 16 | C 19
Check [19, 19]
S c+r+  | R 19 | C 19
Check [19, 19]
S c+    | R 19 | C 19
Check [19, 19]
S c+r-  | R 19 | C 19
Check [19, 19]
S r+    | R 19 | C 19
Check [19, 19]
S c-r+  | R 19 | C 19
The four coherent numbers, which have the highest product:
a => [12,6] = 89
b => [13,5] = 94
c => [14,4] = 97
d => [15,3] = 87

Hab ich irgendwo n Denkfehler?

Pörl.

View all threads created 2007-12-15 12:19.