Frage zur Automatisierung von Formulareingaben (gelöst) (Perl/CGI)

[thread]16584[/thread]

Frage zur Automatisierung von Formulareingaben [gelöst]

Tags: perl5 CGI Ähnliche Threads

Leser: 22

Articles: hide open all | hide show old branches

+8 replies

Kuerbis

2011-08-02 12:39

User since
2011-03-20
947 Artikel
BenutzerIn
[default_avatar]

Hallo!

Code (html): (dl )

<!DOCTYPE html>
<body>
<br /><br />
<form>
        Vorname&nbsp;&nbsp;&nbsp;: 
        <input type="text" name="vorname" size="40" autofocus="autofocus" /> 
        <br /><br />
        Nachname:
        <input type="text" name="nachname" size="40" /> 
        <br /><br />
        Strasse&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;:
        <input type="text" name="strasse" size="40" /> 
        <br /><br />
        Nummer&nbsp;&nbsp;&nbsp;:
        <input type="number" name="nummer" size="5" /> 
        <br /><br />
        Ort&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;:
        <input type="text" name="ort" size="40" /> 
        <br /><br />
        PLZ&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;:
        <input type="number" name="plz" size="5" /> 
        <br /><br /><br /><br />
        Weiter&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;:
        <input type="submit" />
</form>
</body>
</html>

Ist es möglich diese Seite so zu verändern, dass nach einer Eingabe von `Vorname` und `Nachname` die restlichen Felder automatisch ausgefüllt werden, wenn eine solche Datenbankabfrage nur einen Eintrag liefert?

Code (perl): (dl )

1
2

$sth = $dbh->prepare( "SELECT strasse, nummer, ort, plz FROM $table WHERE vorname == ? AND nachname == ?" );
$sth->execute( $vorname, $nachname );

Last edited: 2011-08-02 12:50:04 +0200 (CEST)

+6 replies

GwenDragon

2011-08-02 12:58

User since
2005-01-17
14711 Artikel
Admin1

1) Nur ein Formular mit Name und Nachname anzeigen und diese dann eingeben lassen. Dann die Abfrage an die Datenbank machen.
Existiert ein Datensatz, lässt du ihn komplett anzeigen, in dem du dann alle Werte im Formular ausgibst.
Existiert kein Datensatz, zeigst du das Formular mit allen Feldern an, lässt dann die Daten eingeben und absenden.

2) Ansonsten ginge das im Hintergrund (also direkt nach der Eingabe beider Felder) nur mit AJAX.
Nach der Eingabe von Vor- und Name müsste das Javascript über einen speziellen Parameter an das Perlprogramm senden, damit aus der Datenbank auch die restliche Werte abgefragt werden.

Noch Fragen? Weiß du wie sowas geht?
Last edited: 2011-08-02 12:59:32 +0200 (CEST)

die Drachin Gwen

Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten

+4 replies

Kuerbis

2011-08-02 13:27

User since
2011-03-20
947 Artikel
BenutzerIn
[default_avatar]

Wie die zweite Möglichkeit funktioniert (AJAX), weiss ich nicht.

+3 replies

GwenDragon

2011-08-02 15:27

User since
2005-01-17
14711 Artikel
Admin1

Welche Möglichkeit willst du denn wirklich verwenden?

die Drachin Gwen

Meine Perl-Artikel · perldev – verschiedene Perl-Versionen unter Windows starten

+2 replies

Kuerbis

2011-08-02 20:26

User since
2011-03-20
947 Artikel
BenutzerIn
[default_avatar]

Zuerst die erste, und wenn die funktioniert eventuell die zweite.

Kuerbis

2011-08-03 08:09

User since
2011-03-20
947 Artikel
BenutzerIn
[default_avatar]

Code (perl): (dl )

#!/usr/local/bin/perl
use warnings;
use 5.014;
use Mojolicious::Lite;
use DBI qw(:sql_types);

my $db = 'adressen_db';
my $dbh = DBI->connect( "DBI:SQLite:dbname=$db", "", "", {} );
$dbh->{RaiseError} = 1;
$dbh->{PrintError} = 0;
$dbh->{AutoCommit} = 1;
$dbh->{sqlite_unicode} = 1;
$dbh->do("PRAGMA cache_size = 400000");
$dbh->do("PRAGMA synchronous = OFF");

my $table = 'adressen';
#$dbh->do( "CREATE TABLE $table ( vorname TEXT, nachname TEXT, steuernummer TEXT PRIMARY KEY, strasse, nummer INTEGER, ort TEXT, plz INTEGER )" );


get '/namen' => sub {
        shift->render( 'namen' );
};

get '/steuernummer' => sub {
        my $self = shift;
        my $vorname = $self->param('vorname');
        my $nachname = $self->param('nachname');
        my $sth = $dbh->prepare( "SELECT steuernummer FROM $table WHERE vorname == ? AND nachname == ?" );
        $sth->execute( $vorname, $nachname );
        my @steuernummern;
        while ( my $row = $sth->fetchrow_hashref ) {
                push @steuernummern, $row->{steuernummer};
        }
        $self->stash( vorname => $vorname );
        $self->stash( nachname => $nachname );
        $self->stash( steuernummern => [ @steuernummern ] );
        $self->render( 'steuernummer' );
};

get '/adresse' => sub {
        my $self = shift;
        my $steuernummer = $self->param('steuernummer');
        my $vorname = $self->param('vorname');
        my $nachname = $self->param('nachname');
        my $sth = $dbh->prepare( "SELECT strasse, nummer, ort, plz FROM $table WHERE steuernummer == ?" );
        $sth->execute( $steuernummer );
        my $ref = $sth->fetchall_arrayref; 
        $self->stash( vorname => $vorname );
        $self->stash( nachname => $nachname );
        $self->stash( steuernummer => $steuernummer );
        $self->stash( strasse => '' );
        $self->stash( nummer => '' );
        $self->stash( ort => '' );
        $self->stash( plz => '' );
        $self->stash( exists => 0 );
        if ( @$ref == 1 and @{$ref->[0]} == 4 ) {
                my ( $strasse, $nummer, $ort, $plz ) = @{$ref->[0]};
                $self->stash( strasse => $strasse );
                $self->stash( nummer => $nummer );
                $self->stash( ort => $ort );
                $self->stash( plz => $plz );
                $self->stash( exists => 1 );
        }
        $self->render( 'adresse' );
};

get '/database' => sub {
        my $self = shift;
        my $vorname = $self->param('vorname');
        my $nachname = $self->param('nachname');
        my $steuernummer = $self->param('steuernummer');
        my $strasse = $self->param('strasse');
        my $nummer = $self->param('nummer');
        my $ort = $self->param('ort');
        my $plz = $self->param('plz');
        my $exists = $self->param('exists');    
        if ( not $exists ) {
                my $sth = $dbh->prepare( "INSERT INTO $table ( vorname, nachname, steuernummer, strasse, nummer, ort, plz ) VALUES ( ?, ?, ?, ?, ?, ?, ? )" );
                $sth->execute( $vorname, $nachname, $steuernummer, $strasse, $nummer, $ort, $plz );
        }
        $self->render( 'database' );
};

app->start;


__DATA__
@@ namen.html.ep
<!DOCTYPE html>
<html> 
        <head>
        </head>
        <body>
                <br /><br />
                <form action="steuernummer">
                        Vorname&nbsp;&nbsp;&nbsp;: <input type="text" name="vorname" required="required" size="40" maxlength="80" autofocus="autofocus" autocomplete="on" /> 
                        <br /><br />
                        Nachname: <input type="text" name="nachname" required="required" size="40" maxlength="80" autocomplete="on" /> 
                        <br /><br /><br /><br />
                        Weiter&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="submit" />
                </form>
        </body>
</html> 

@@ steuernummer.html.ep
<!DOCTYPE html>
<html> 
        <head>
        </head>
        <body>
                <br /><br />
                <form action="adresse">
                        <input type='hidden' name='vorname' value="<%= $vorname %>">
                        <input type='hidden' name='nachname' value="<%= $nachname %>">
% if ( @$steuernummern == 0 ) {
                        Steuernummer: <input type="text" name="steuernummer" required="required" size="20" maxlength="20" autofocus="autofocus" /> 
% } elsif ( @$steuernummern == 1 ) {
                        Steuernummer: <input type="text" name="steuernummer" value="<%= $steuernummern->[0] %>" required="required" size="20" maxlength="20" autofocus="autofocus" /> 
% } else {
                        Steuernummer: <input type="text" name="steuernummer" required="required" size="20" maxlength="20" list="list_steuernummer" autofocus="autofocus" autocomplete="off" /> 
                        <datalist id="list_steuernummer">
%                       for my $value ( @{$steuernummern} ) {
                                <option value="<%= $value %>" />
%                       }
                        </datalist>
% }
                        <br /><br /><br /><br />
                        Weiter&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="submit" />
                </form>
        </body>
</html> 

@@ adresse.html.ep
<!DOCTYPE html>
<html> 
        <head>
        </head>
        <body>
                <br /><br />
                <h1<%= "$steuernummer" %></h1>
                <form action="database">
                        <input type='hidden' name='vorname' value="<%= $vorname %>">
                        <input type='hidden' name='nachname' value="<%= $nachname %>">
                        <input type='hidden' name='steuernummer' value="<%= $steuernummer %>">
                        <input type='hidden' name='exists' value="<%= $exists %>">
                        Strasse&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="text" name="strasse" value="<%= $strasse %>" required="required" size="40" maxlength="80" autofocus="autofocus" autocomplete="on" /> 
                        <br /><br />
                        Nummer&nbsp;&nbsp;&nbsp;: <input type="number" name="nummer" value="<%= $nummer %>" required="required" size="5" maxlength="5" autocomplete="on" /> 
                        <br /><br />
                        Ort&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="text" name="ort" value="<%= $ort %>" required="required" size="40" maxlength="80" autocomplete="on" /> 
                        <br /><br />
                        PLZ&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="number" name="plz" value="<%= $plz %>" required="required" size="5" maxlength="5" autocomplete="on" /> 
                        <br /><br /><br /><br />
                        Weiter&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;: <input type="submit" />
                </form>
        </body>
</html> 

@@ database.html.ep
<!DOCTYPE html>
<html> 
        <head>
        </head>
        <body>
                <p>Klicken Sie auf <a href='namen'>weiter</a> um eine weiteren Eintrag hinzuzufügen.</p>
        </body>
</html>

Soweit ich es getestet habe, funktioniert es; aber vielleicht kann man hier noch etwas verbessern.

Kuerbis

2011-08-09 10:42

User since
2011-03-20
947 Artikel
BenutzerIn

Für die AJAX Methode werde ich eventuell einen eigenen Thread öffnen.

rosti

2011-08-02 21:20

User since
2011-03-19
3417 Artikel
BenutzerIn

Quote
Ist es möglich diese Seite so zu verändern, dass nach einer Eingabe von `Vorname` und `Nachname` die restlichen Felder automatisch ausgefüllt werden, wenn eine solche Datenbankabfrage nur einen Eintrag liefert?

Klar ist das möglich. Führe das Statement aus und prüfe mit $sth->rows wieviele Records es gibt.

Was ich für Dein Vorhaben empfehlen würde, ist ein Statement mit match() und against(), siehe Thema Volltextsuche zur DB Deiner Wahl.

View all threads created 2011-08-02 12:39.