Tk: Toplevel funktioniert nicht bei 2tem Aufruf (Graphische Oberflächen)

[thread]16026[/thread]

Tk: Toplevel funktioniert nicht bei 2tem Aufruf

Tags: Tk Similar Threads

Readers: 19

Articles: hide open all | hide show old branches

+10 replies

guest Juergen

2011-03-02 08:51

Hallo zusammen,

leider muss ich wieder eure Hilfe in nspruch nehmen.
Ich beutze Tk zumerstellen meiner GUI.
Wenn ich einen Button bediene (als drücke) springe ich in eine sub und erzeuge mir hier ein Toplevel-Widget von $mw.
Das Toplevel hat wiederum andere Widgets wie MListBox und Buttons usw.
Wenn das Toplevel zum ersten mal gestartet wird, funktioniert alles einwandfrei.
Über einen Button "quit" rufe ich ein toplevel->destroy(); auf und das Toplevel ist weg.
Rufe ich aus dem MainWindow per Button-Click das Toplevel erneut auf, so funktioniert das Toplevel nicht mehr: es wird zwar angezeigt, aber sämtliche sub's innerhalb funktionieren nicht mehr :(

Was mach ich den falsch?
Kann ein Toplevel immer nur einmal aufgerufen werden? Das wär ja ganz schön doof...

Bitte um Hilfe

Anbei die Sub in das das Toplevel erstellt und die Datenbearbeitet werden:

Code (perl): (dl )

sub edit_times{
        # diese Funktion öffnet ein neues Toplevel-Widget
        # hier können bereits eingetragene Zeiten bearbeitet werden und
        # neue Tätigkeiten angelegt werde
        tie my @arr_data_set_timefile, 'Tie::File', $file_name_path_act_month or die $!;
        my @arr_ref_mlistbox_timedata = tied_times_to_2d_array_ref(\@arr_data_set_timefile);
        untie @arr_data_set_timefile;
        
        my $toplevel_edit_times = $mw->Toplevel(
                -title => 'Times in file',
                -background => 'white',
        );
        $toplevel_edit_times->transient($mw);
        $toplevel_edit_times->focusForce();
        $toplevel_edit_times->geometry('1000x500'); 
        my $MListbox_edit_times = $toplevel_edit_times->Scrolled('MListbox',
                -columns=>[
                        [-text=>'Datum Beginn' ,-width=>14], #, -comparecommand => sub { $_[0] <=> $_[1]}],
                        [-text=>'Uhrzeit Beginn', -width => 14],
                        [-text=>'Projekt', , -width => 24],
                        [-text=>'Arbeitspaket', -width=>25],
                        [-text=>'Task', -width => 50],
                        [-text=>'Datum Ende', -width => 14],
                        [-text=>'Uhrzeit Ende', -width => 14],#, -comparecommand => sub { $_[0] <=> $_[1]}],
                ],
                -takefocus => 1,
        )->pack(-fill => 'both', -expand => 1, -side => 'top');

        my $Frame_edit_times_workplace = $toplevel_edit_times->Frame()->pack(-fill=>'x', -expand=>1, -side=>'top');
        my $Entry_Date = $Frame_edit_times_workplace->LabEntry(-label=>'Datum', -width=>10)->pack(-side=>'left');
        my $Entry_Time_start = $Frame_edit_times_workplace->LabEntry(-label=>'Beginn', -width=>6)->pack(-side=>'left');
        my $Entry_Time_stop = $Frame_edit_times_workplace->LabEntry(-label=>'Ende', -width=>6)->pack(-side=>'left');
        my $JBrowseEntry_edit_times_Projects = $Frame_edit_times_workplace->JBrowseEntry(
                -label => 'Projekt:',
                -labelPack => [-side => 'top', -anchor => 'e'],
                -variable => \$project_selected,
                -state => 'normal',
                -choices => [@arr_projects,keys(%hoa_additionals)],
                -width  => 12,
                -browsecmd => \&set_JBrowseEntry_choices,
                -tabcomplete => 1,
        )->pack(
                -side   => 'left',
                -pady => '2',
                -anchor => 'w'
        );
        my $JBrowseEntry_edit_times_Workpackages = $Frame_edit_times_workplace->JBrowseEntry(
                -label => 'Workpackage:',
                -labelPack => [-side => 'top', -anchor => 'e'],
                -variable => \$workpackage_selected,
                -state => 'normal',
                -choices => \@arr_work_packs,
                -width  => 20,
                #-validate => 'focusin',
                #-validatecommand => \&set_JBrowseEntry_choices,
        )->pack(
                -side   => 'left',
                -pady => '2',
                -anchor => 'w'
        );
        my $Entry_Task = $Frame_edit_times_workplace->LabEntry(-label=>'Task')->pack(-fill=>'x', -expand=>1, -side=>'left');
        my $Frame_edit_times_buttonmenue = $toplevel_edit_times->Frame()->pack(-fill=>'x', -expand=>1, -side=>'top');
        my $Button_new_task = $Frame_edit_times_buttonmenue->Button(-text=>'add new task', -command=>\&add_new_task)->pack(-padx=>'2', -pady=>'2', -side=>'left',);
        my $Button_quit_edit_task = $Frame_edit_times_buttonmenue->Button(-text=>'quit', -command=>[\&quit_edit_times, \$toplevel_edit_times])->pack(-padx=>'2', -pady=>'2', -side=>'left', );
        $MListbox_edit_times->bindRows("<Button-1>",\&get_mlistbox_cur_selection);

        fill_mlistbox(\$MListbox_edit_times);

        my @arr_ref_time_data;
        foreach my $cur_line (@arr_data_set_timefile){
                print $;
        }
        my $index_cur_selection;
        sub get_mlistbox_cur_selection{
                $index_cur_selection = $MListbox_edit_times->curselection();
                # hole die Einträge der Selektion der MListbox
                my @arr_cur_sel = $MListbox_edit_times->getRow($index_cur_selection);
                # Lösche die alten Eintraege
                $Entry_Date->delete(0,'end');
                $Entry_Time_start->delete(0,'end');
                $Entry_Time_stop->delete(0,'end');
                $Entry_Task->delete(0,'end');
                # Trage die markierten Daten ein:
                $Entry_Date->insert('end',$arr_cur_sel[0]);
                $Entry_Time_start->insert('end',$arr_cur_sel[1]);
                $JBrowseEntry_edit_times_Projects->activate(get_mlistbox_choice_index(\$JBrowseEntry_edit_times_Projects,$arr_cur_sel[2]));
                $JBrowseEntry_edit_times_Workpackages->activate(get_mlistbox_choice_index(\$JBrowseEntry_edit_times_Workpackages,$arr_cur_sel[3]));
                $Entry_Task->insert('end',$arr_cur_sel[4]);
                $Entry_Time_stop->insert('end',$arr_cur_sel[6]);
        }

        sub add_new_task{
                # übernimmt die Eingaben und hängt sie einfach an die Zeitliste an
        }

        sub fill_mlistbox{
                my $listbox_widget = shift;
                ${$listbox_widget}->delete(0,'end');
                ${$listbox_widget}->insert('end',@arr_ref_mlistbox_timedata);
        }

        sub get_mlistbox_choice_index{
                # diese Funktion bekommt einen String und sucht die Index-Nummer
                # der Auwahl-Liste des übergebenen Stings
                my $ref_jbe = shift;
                my $string_value = shift;
                my $index=-1;
                my @arr_mlistbox_choices = ${$ref_jbe}->choices();
                my $counter=0;
                foreach my $cur_elem (@arr_mlistbox_choices){
                        DEBUG "Vergleiche ".$string_value." mit ".$cur_elem."\n"." und Index ist z.Zt. ".$index;
                        if($string_value eq $cur_elem){
                                $index = $counter;
                        }
                        $counter++;
                }
                return($index);
        }
        
        sub quit_edit_times{
                sort @arr_data_set_timefile;
                untie @arr_data_set_timefile;
                $toplevel_edit_times->destroy if Tk::Exists($toplevel_edit_times);
        }
}

Danke und Grüße
Jürgen
Last edited: 2011-03-02 10:22:52 +0100 (CET)

pktm

2011-03-02 16:42

User since
2003-08-07
2921 articles
BenutzerIn

Die Doku zu Tk::Toplevel verweist für die Methoden auf Tk::Widget und da steht zu $widget->destroy():

Quote
he perl object $widget continues to exist while references to it still exist, e.g. until variable goes out of scope. However any attempt to use Tk methods on the object will fail. Exists($widget) will return false on such objects.

Vllt. ist $widget->UnmapWindow() was für dich?

Grüße, pktm
http://www.intergastro-service.de (mein erstes CMS :) )
+8 replies

Kalle

2011-03-04 00:05

User since
2007-03-18
48 articles
BenutzerIn
[default_avatar]

Hallo Jürgen,

ich kann dir keine Details erklären, aber deinen Quit Button kannst du wiederbeleben, indem du den Destroy Befehl in den Quit Button mitaufnimmst.

Code (perl): (dl )

-command=>sub {quit_edit_times();$toplevel_edit_times->destroy;}

oder prinzipiell deinen subs die benötigten widgets als Parameter übergibst.

Mein größtes Tk Programm benutzt auch an mehreren Stellen Toplevel Windows, die immer wieder aufgerufen werden können, allerdings immer nur eines gleichzeitig. Öffne ich dasselbe Fenster ein zweitesmal und schliesse das erste, funktioniert destroy für das zweite Fenster nicht mehr, also pass ich halt auf, daß es nur einmal geöffnet werden kann.

Für Fenster die gerne mehrfach mit dem gleichen Inhalt geöffnet und benutzt werden können, benutze ich MainWindow und nicht Toplevel.

Auch hab ich keine subs in subs definiert, auch wenn ich dadurch teilweise erheblich mehr Parameterübergaben habe (muss wohl mal einen Grund gehabt haben damals).
Die sub in sub Sache erklärt dann auch deine "will not stay shared" warnings.

Hoffetrotzdemgeholfenzuhaben :)

Kalle

+7 replies

guest Juergen

2011-03-29 09:17

Hallo zusammen,

ich nochmal...
Ich kriegs einfach nicht richtig hin... :(

Wieso funktioniert das nur beim ersten mal?
Darf in keine "Subs" in "Subs" verwenden?

Wie könnte ich denn das sonst sauber trennen?
Sollte ich die gesamte GUI in ein eigenes Modul packen?
Wäre sehr schön, aber wie geht das?
Kann mir das bitte jemand an einem ganz einfach Beispiel zeigen bitte?

Grüße Jürgen
Last edited: 2011-03-29 10:29:41 +0200 (CEST)

pq

2011-03-29 10:43

User since
2003-08-04
12208 articles
Admin1

Guest Juergen
Darf in keine "Subs" in "Subs" verwenden?

solltest du in der regel nicht. was sollen die bezwecken? sie sind eh global sichtbar.
wenn du closures willst, nimm anonyme subs.
Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live. -- Damian Conway in "Perl Best Practices"
lesen: Wie frage ich & perlintro brian's Leitfaden für jedes Perl-Problem
+5 replies

pktm

2011-03-29 10:48

User since
2003-08-07
2921 articles
BenutzerIn

Ja, kleine Mini-Beispiele sind immer gut. Versuche doch mal, dein Problem auch auf ein solches Mini-Beispiel zu reduzieren und hier reinzustellen. Eventuell können dir dann mehr Leute helfen.

Hier mal eine Variante mit MapWindow und UnMapWindow. Probiers mal aus, eventuell ist es das, was du suchst.

Code (perl): (dl )

#!perl

use strict;
use warnings;
use Tk;

my $mw = tkinit();

my $toplevel = $mw->Toplevel();

$mw->Button(-text => 'show/hide', -command => [sub{ show_hide(@_); }, $toplevel],)->pack();

$mw->MainLoop();

sub show_hide {
        my $toplvl = shift;
        
        if( $toplvl->viewable ) {
                print "hide widget\n";
                $toplvl->UnmapWindow();
        }else{
                print "display widget\n";
                $toplvl->MapWindow();
        }
        
} # /show_hide

Ich weiß allerdings nicht, ob das das Mittel der Wahl ist. Vllt. kann Kalle das ja mal mit destroy() nachbauen.

http://www.intergastro-service.de (mein erstes CMS :) )

+4 replies

guest Juergen

2011-03-29 16:43

Vielen Dank für Eure Antworten erstmal.

Vielleicht bin ich gänzlich auf dem falschen Dampfer und erklär mal was ich eigentlich machen möchte:
Zum Erfassen meiner Arbeitszeiten hab ich mir mein Script geschrieben.
Damit das Ganze zu bedienen ist, habe ich eine GUI mit TK gemacht.
bei mir ist das dann iumer so, das alles in einer Date ist: script.pl

Ich speichere also munter meiner Zeiten und Tätigkeiten ab.
Nun habe ich einen Button programmiert, mit dem ein neues Fenster geöffnet wird.
Hier kann ich nun meine Zeiten angucken und auch verändern.
Beim Schließen und erneutem wiederöffnen des Fensters habe ich die besagten Probleme.

@pq:
"Sub in Sub" habe ich deshalb, weil ich von dem Button aus, in eine Sub springe. In dieser SUB wird das Toplevel-Widget mit all seinem Inhalt aufgebaut. Desweiteren muss ich dann natürlich auf gewisse "klicks" im Toplevel reagieren...und habe mir dafür eben SUBs definiert.

Aber aus Euren beiden Antworten schließe ich, dass dies wohl gänzlich der falsche Ansatz ist.
Auch ich hätte es gern schöner strukturiert..evtl die Bedatung sämtlicher GUI-Sachen in einem Modul "script_juergen_GUI.pm" vielleicht?

Nur: wie geht das oder besser: wie wird es denn richtig gemacht?

Grüße Jürgen
Last edited: 2011-03-29 16:47:50 +0200 (CEST)

pq

2011-03-29 17:06
User since
2003-08-04
12208 articles
Admin1
statt:
Code (perl): (dl )

1 2 3

sub get_mlistbox_choice_index{ ... } ...->activate(get_mlistbox_choice_index(...));
Code (perl): (dl )

1 2 3

my $get_mlistbox_choice_index = sub { ... } ...->activate($get_mlistbox_choice_index->(...));
dann werden die subs jedesmal neu definiert. und die warnungen wegen "will not stay shared" sollten dann auch verschwinden.
Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live. -- Damian Conway in "Perl Best Practices"
lesen: Wie frage ich & perlintro brian's Leitfaden für jedes Perl-Problem

Kalle

2011-03-30 16:36

User since
2007-03-18
48 articles
BenutzerIn
[default_avatar]

Hallo Jürgen,

hier ein paar Beispiele:

kleines Beispiel für Toplevel Windows.
Da ich hier sowohl für das Main Window als auch für die Toplevel Windows die gleichen Widgets benutze, hab ich sie einfach mal in eine sub ausgelagert.
Mit dem Button kann "Create Toplevel Window" Button kann man nun vom Main Window als auch von bereits erzeigten Toplevel Windows aus neue Toplevels erstellen.
Dabei hängen alle erzeugten Toplevel Windows hängen am Main Window und sind voneinander unabhängig.

So ungefähr:

Code: (dl )

          |- Toplevel
          |- Toplevel
MainWindow|
          |- Toplevel
          |- Toplevel

Code (perl): (dl )

#!/usr/local/bin/perl

use strict;
use warnings;
use Tk;


#main window
my $mw = MainWindow->new(-title=>'Main Window');

create_widgets($mw);

MainLoop();



sub create_toplevel_window {
  # create toplevel window
  my $top=$mw->Toplevel(-title=>"Toplevel Window");
  # create toplevel frames
  create_widgets($top);
}

sub create_widgets {
  my $thiswindow = shift;
  my $frame_top = $thiswindow->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $frame_bottom = $thiswindow->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $edit_button = $thiswindow->Button(-text => "Create Toplevel Window",-state => 'normal',-width => 30,-activebackground=>'gray', -command => sub{create_toplevel_window()})->pack (-in => $frame_top,-side=>'top',-padx => 3,-pady => 5);
  my $mw_close_button = $thiswindow->Button(-text => 'Close',-background=>'gray',-width=>60,-command => sub{$thiswindow->destroy})->pack(-in=>$frame_bottom,-side => 'top',-expand => '0',-fill => 'x');
}

Im folgenden Beispiel hänge ich die Toplevel Windows an das Window, das den Aufruf ausführt.
Erzeuge ich damit mehrere Toplevels und schliesse ein übergeordnetes Window, dann werden alle daran hängenden und darunterliegenden Windows geschlossen.
So ungefähr:

Code: (dl )

                     |-Toplevel
          |- Toplevel|
          |          |-Toplevel|-Toplevel
          |                    |-Toplevel
          |
MainWindow|
          |- Toplevel|-Toplevel
          |- Toplevel

Code (perl): (dl )

#!/usr/local/bin/perl

use strict;
use warnings;
use Tk;

#main window
my $mw = MainWindow->new(-title=>'Main Window');

create_widgets($mw);

MainLoop();


sub create_toplevel_window {
  my $thiswindow = shift;
  # create toplevel window
  my $top=$thiswindow->Toplevel(-title=>"Toplevel Window");
  # create toplevel frames
  create_widgets($top);
}

sub create_widgets {
  my $thiswindow = shift;
  my $frame_top = $thiswindow->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $frame_bottom = $thiswindow->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $edit_button = $thiswindow->Button(-text => "Create Toplevel Window",-state => 'normal',-width => 30,-activebackground=>'gray', -command => sub{create_toplevel_window($thiswindow)})->pack (-in => $frame_top,-side=>'top',-padx => 3,-pady => 5);
  my $mw_close_button = $thiswindow->Button(-text => 'Close',-background=>'gray',-width=>60,-command => sub{$thiswindow->destroy})->pack(-in=>$frame_bottom,-side => 'top',-expand => '0',-fill => 'x');
}

Das dritte Beispiel dürfte deinem Anliegen nahe kommen. Aus dem Main Window wird ein Toplevel gestartet. Im Toplevel werden daten geladen und in einer MListbox angezeigt.
Ein Add Button sorgt dafür, daß neue Daten hinzugefügt werden können.
Der Refresh Button ist nicht wirklich bedeutsam, da die MListbox nach dem Hinzufügen durch die sub fill_tasklist refreshed wird. aber der Refresh Button bewirkt auch eine Dumper Ausgabe in der Shell.

Code (perl): (dl )

#!/usr/local/bin/perl

use strict;
use warnings;

use Tk;
use Tk::MListbox;
use Tk::DialogBox;
use Tk::LabEntry;
use Data::Dumper;

#main window
my $mw = MainWindow->new(-title=>'Main Window');

my $frame_top = $mw->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
my $frame_bottom = $mw->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
my $edit_button = $mw->Button(-text => "Edit Tasks",-state => 'normal',-width => 30,-activebackground=>'gray', -command => sub{edit_tasks()})->pack (-in => $frame_top,-side=>'top',-padx => 3,-pady => 5);
my $mw_close_button = $mw->Button(-text => 'Close',-background=>'gray',-width=>60,-command => sub{$mw->destroy})->pack(-in=>$frame_bottom,-side => 'top',-expand => '0',-fill => 'x');


MainLoop();


sub edit_tasks {
  # load your data
  my $tasks=load_data();

  # create toplevel window
  my $top=$mw->Toplevel(-title=>"Toplevel Window");

  # create toplevel frames
  my $frame_top = $top->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $frame_bottom = $top->Frame-> pack(-side=>'top',-fill => 'both', -anchor,'nw');
  my $tasklist = $top->Scrolled('MListbox',
                        -scrollbars => 'ose',-separatorcolor => 'darkgrey',-height=>15,-width=>300)->pack(-in=>$frame_top,-expand=>1,-fill=>'both');
  $tasklist->columnInsert('end',-text=>'Task',-width=>15);
  $tasklist->columnInsert('end',-text=>'Date',-width=>15);
  $tasklist->columnInsert('end',-text=>'Time',-width=>15);

  #buttons
  my $add_button = $top->Button(-text => "Add Task",-state => 'normal',-width => 30,-activebackground=>'gray', -command => sub{add_task($top,\$tasks); fill_tasklist($tasklist,\$tasks);})->pack (-in => $frame_top,-side=>'top',-padx => 3,-pady => 5);
  my $refresh_button = $top->Button(-text => "Refresh",-state => 'normal',-width => 30,-activebackground=>'gray', -command => sub{fill_tasklist($tasklist,\$tasks);})->pack (-in => $frame_top,-side=>'top',-padx => 3,-pady => 5);
  my $mw_close_button = $top->Button(-text => 'Close',-background=>'gray',-width=>60,-command => sub{$top->destroy})->pack(-in=>$frame_bottom,-side => 'top',-expand => '0',-fill => 'x');

  fill_tasklist($tasklist,\$tasks);
}

sub add_task {
  my $parent=shift;
  my $tasksref=shift;
  my $tasks=$$tasksref;
  my $ewidth=40;

  my $thistaskname;
  my $thisdate;
  my $thisstart;
  my $thisstop;

  my $add_dialog = $parent->DialogBox( -title   => "Add task",-buttons => [ "Save", "Cancel" ] );

  my $task_entry=$add_dialog->LabEntry(-label => "Task          ", -bg=>'white',
         -labelFont => 'monospaced8',
         -labelPack => [-side => "left", -anchor => "w"],
         -width => 30,
         -textvariable => \$thistaskname)->pack(-side => "top", -anchor => "nw", -fill=>'x');

  my $date_entry1=$add_dialog->LabEntry(-label => "Date          ",  -bg=>'white',
         -labelFont => 'monospaced8',
         -labelPack => [-side => "left", -anchor => "w"],
         -width => $ewidth,
         -textvariable => \$thisdate)->pack(-side => "top", -anchor => "nw", -fill=>'x');

  my $time_start_entry=$add_dialog->LabEntry(-label => "Time Start ",  -bg=>'white',
         -labelFont => 'monospaced8',
         -labelPack => [-side => "left", -anchor => "w"],
         -width => $ewidth,
         -textvariable => \$thisstart)->pack(-side => "top", -anchor => "nw", -fill=>'x');

  my $time_stop_entry=$add_dialog->LabEntry(-label => "Time Stop ",  -bg=>'white',
         -labelFont => 'monospaced8',
         -labelPack => [-side => "left", -anchor => "w"],
         -width => $ewidth,
         -textvariable => \$thisstop)->pack(-side => "top", -anchor => "nw", -fill=>'x');

  $task_entry->focus; #set focus depending on type of command (add,edit) and erros (alias,user or password invalid)
  my $clicked_button = $add_dialog->Show;

  if ($clicked_button eq 'Save') {
    my $thistime="$thisstart\-$thisstop";
    push(@{$tasks->{$thistaskname}->{$thisdate}},$thistime);
  }
}


sub fill_tasklist {
  my $tasklistwidget=shift;
  my $tasksref=shift;
  my $tasks=$$tasksref;

  $tasklistwidget->delete(0,'end');
  foreach my $thistaskname (sort keys %{$tasks}) {
    foreach my $thisdate (sort keys %{$tasks->{$thistaskname}}) {
      foreach my $thistime (@{$tasks->{$thistaskname}->{$thisdate}}) {
        my @row;
        push(@row,$thistaskname);
        push(@row,$thisdate);
        push(@row,$thistime);
        $tasklistwidget->insert('end', [@row]);
        $tasklistwidget->see('end');
        $tasklistwidget->update;
      }
    }
  }
  print Dumper($tasks);
}



sub load_data {
  my $tasks;
  my $pos= tell(DATA);
  while  (<DATA>) {
    chomp $_;
    my @line=split(/,/,$_);
    my $thistaskname=$line[0];
    my $thisdate=$line[1];
    my $thisstart=$line[2];
    my $thisstop=$line[3];
    my $thistime="$thisstart\-$thisstop";
    push(@{$tasks->{$thistaskname}->{$thisdate}},$thistime);
  }
  seek DATA, $pos, 0;
  return $tasks;
}

__DATA__
Task1,20110329,08:00,12:00
Task2,20110329,13:00,18:00
Task3,20110330,09:00,17:00

Gruß

Kalle

guest Juergen

2011-03-31 12:44

Vielen Dank für Eure Mühen!

@pq: diese Darstellungsweise kenne /bzw. kannte ich noch gar nicht!
Ich habe oft "will not stay shared" Warnungen.
Das muss ich gleich heute Abend mal anschauen nud testen!

@Kalle: auch hier brauche ich ein paar Tage, um mir das in Ruhe am Abend angucken zu können.

Nochmal Danke und ich melde mich dann in ein paar Tagen mit einem "Fazit"

Grüße Jürgen
Last edited: 2011-03-31 12:48:38 +0200 (CEST)

View all threads created 2011-03-02 08:51.