use Tk;
require Tk::LabEntry;
$mw = new MainWindow;

foreach (qw/Vorname Nachname Strasse PLZ Ort/) {
        $mw->LabEntry(
               
       -label => $_,
               
       -textvariable => \$results{$_}
        )->pack();
}
$mw->Button(-text => "Ok", -command => sub { print "$_ => $results{$_}
" for keys %results })->pack();
$mw->Button(-text => "Exit", -command => sub { exit } )->pack();

MainLoop;

#!/usr/bin/perl
use strict;
use warnings;
use Tk;

use constant PI => 3.1415927;
my $Size = 100;

my @Weekdays = qw/Son Mon Die Mit Don Fre Sam/;
my ($HSec, $HMin, $HHour, $Date);
my $Mw = MainWindow->new;
my $HFace = $Mw->Canvas (-width => 2*$Size, -height => 2*$Size)->pack;
my $DText = $Mw->Label (-textvariable => \$Date)->pack;

$HFace->createLine (tc(0.9, $_), tc(1, $_)) for (0..11);

drawtime();
$Mw->repeat (1000, \&drawtime);
$Mw->MainLoop();

sub drawtime {
    my ($s, $m, $h, $dy, $mn, $yr, $wd) = (localtime())[0..6];
    $Date = sprintf("%s, %02d.%02d.%04d", $Weekdays[$wd], $dy, $mn+1, $yr+1900);
    $h+=$m/60;
    for ($HSec, $HMin, $HHour) {
        $HFace->delete($_) if $_;
    }
    $HSec  = $HFace->createLine ($Size, $Size, tc(0.88, $s/5));
    $HMin  = $HFace->createPolygon (tc(0.85, $m/5), tc(0.05, ($m/5+4)), tc(0.05, ($m/5-4)));
    $HHour = $HFace->createPolygon (tc(0.5, $h), tc(0.05, $h+4), tc(0.05, $h-4));
    $Mw->update;
}

sub tc {
    my ($scale, $time) = @_;
    return ($Size*$scale*sin($time*PI/6)+$Size,
           -$Size*$scale*cos($time*PI/6)+$Size);
}

#!/usr/bin/perl
use strict;
use Tk;
require Tk::Dialog;

my $msg = <<"EOT";
Herzlich Willkommen !
Der Computer wird nun eine Zahl zwischen 1 und 10000 wählen.
Danach müssen Sie diese Zahl erraten. Geben Sie dazu die Zahl
in die Textbox und klicken Sie auf Submit.
EOT

my $num;
my $counter;
my $random = int(rand(10000))+1;
my $mw = MainWindow->new(-background => "#000059",-foreground => "#FFFFFF");
$mw->title("Zahlenspiel");
my $text = $mw->Label(
                      -text => $msg,
                      -background => "#000059",
                      -foreground => "#FFFFFF",
                      -font => "Helvetica",
                     )->pack();
$mw->Entry(-width => 50, -textvariable => \$num)->pack();
$mw->Button(-text => "Zahl prüfen", -command => \&numhandle)->pack();
MainLoop;

sub numhandle {
    if($num =~ /\D/ or $num < 1 or $num > 10000) {
        showinfo("Dies ist keine gültige Zahl.");
    } elsif($num < $random) {
        $counter++;
        showinfo("Deine Zahl ist zu niedrig.");
    } elsif($num > $random) {
        $counter++;
        showinfo("Deine Zahl ist zu hoch.");
    } elsif($num == $random) {
        $counter++;
        my $win = $mw->Dialog(
                              -title => "Gewonnen !",
                              -text => "Herzlichen Glückwunsch !\nDie gesuchte Zahl war: $random\nVersuche: $counter",
                              -buttons => ["Neues Spiel","Spiel verlassen"]
                             )->Show();
        if($win eq "Spiel verlassen") {
            exit(0);
        } else {
            undef $num;
            undef $counter;
            $random = int(rand(10000))+1;
        }
    }
}

sub showinfo {
    my $info = shift;
    my $box = $mw->Dialog(
                          -title => "Fehler!",
                          -text => $info,
                          -bitmap => "error"
                         )->Show();
}